View source for IO入門編

''（このページはHaskellではIOがどのように扱われているかを手っ取り早く紹介することを目的としています。学ぶべきことすべてはお伝えできませんが、どのように動作しているかを感覚はつかめると思います。）''

Haskellでは、副作用は特定の型の値としてエンコードすることで考慮されなければならない、とすることで副作用がある処理と純粋な関数を切り離してきました。<code>(IO a)</code>型の値はアクションです。これは実行されたら<code>a</code>という型の値を生成しますよ、ということを表しています。

いくつか例を見てみましょう：
<haskell>
getLine :: IO String
putStrLn :: String -> IO () -- note that the result value is an empty tuple.
randomRIO :: (Random a) => (a,a) -> IO a -- in practice you will often avoid IO and prefer randomR
</haskell>

ふつうHaskellの評価ではこのような処理は起き得ません。<code>(IO a)</code>型の値はほぼ実行されないまま残ります。実際、コンパイルされたHaskellプログラム中で本当に実行されるように命令されるIOアクションは<code>main</code>だけです。

このような前提を踏まえて、"hello, world"プログラムは次のように書けます。
<haskell>
main :: IO ()
main = putStrLn "Hello, World!"
</haskell>

ここまでいい感じにきていますが、エンド・トゥ・エンドのチェイン・アクションなしでは多くのことはできません。なので、HaskellではIOアクションを繋げる２、３の原則を提示しています。
そのうちの１つは以下の例で表されます。
<haskell>
(>>) :: IO a -> IO b -> IO b
</haskell>
もし<code>x</code> と <code>y</code>がIOアクションなら、<code>(x >> y)</code>は<code>x</code>を実行し、結果を破棄し、そのあと<code>y</code>を実行してその結果を返します。

すごい、これでもう複数の手続きがあるプログラムが書けてしまいます。
<haskell>
main = putStrLn "Hello" >> putStrLn "World"
</haskell>
このコードは"Hello"と"World"を別々の行に表示します。

しかしながら、まだ最初の結果を用いて次の結果が何をするか決めるようなチェイン・アクションの書き方が分かっていません。これは次に示すような 'バインド（束縛）' と呼ばれる操作で実現できます。
<haskell>
(>>=) :: IO a -> (a -> IO b) -> IO b
</haskell>
ここで<code>x >>= f</code>は最初にアクション<code>x</code>を実行して、その結果をつかんで、<code>f</code>に渡してそれが次のアクションが実行される、という一連のアクションを表しています。一連のアクションが実行されると、その結果は全体の計算結果となります。

説明が長くなってしまいましたが、百聞は一見にしかずで、使用例を見ればすぐにわかると思います。
<haskell>
main = putStrLn "Hello, what is your name?"
      >> getLine
      >>= \name -> putStrLn ("Hello, " ++ name ++ "!")
</haskell>

これこそ必要としていたものでした。実際この束縛関数は非常によくできていて、先ほどの<code>(>>)</code>も次のように定義できます。
<haskell>
x >> y = x >>= const y
</haskell>

実際に、ある値をなにもしないでそのまま値を返すようなIOアクションに変換することも非常に大事だとわかりました。これはチェイン・アクションの最後のほうで使うと非常に便利です。これによって、チェインの最後のアクションに処理をゆだねるのではなく、自分たちでどう処理して何を返すか決定することができます。より原始的には
<haskell>
return :: a -> IO a
</haskell>
と書け、いま言ったようなことができます。

do記法はあらゆるHaskellプログラムで見ることができます。do記法を用いた場合、先ほどの例は次のようになります：

<haskell>
main = do putStrLn "Hello, what is your name?"
          name <- getLine
          putStrLn ("Hello, " ++ name ++ "!")
</haskell>

do記法を使った例は実際にdo記法を使わない例と全く同じことであり、Haskellコンパイラによってdo記法を同じものにコンパイルされる。なので、doブロックを見たら、<code>(>>)</code> と <code>(>>=)</code>の連鎖とアクションの結果を取得するのに適切なラムダ式を想像してみてください。
doブロック内の各行にある各アクションは普通に実行され、<code>v <- x</code>となっている行ではアクション<code>x</code>を実行し、結果を変数<code>v</code>に割り当てます。

よく<code>x</code>の位置にアクションでないものを書いてしまうミスをすることがあります。ありがちなのは値を書くことです。もしdoブロック内で変数への束縛をアクションなしに行いたい場合は、<code>let a = b</code>という書き方をすればできます。これは一般的なlet式のように<code>a</code>を<code>b</code>を同じものと定義しますが、doブロック外のスコープには適用されません。

次のような関数はないことに気を付けてください：
<haskell>
unsafe :: IO a -> a
</haskell>
理由は簡単で、これを許してしまうとHaskellの参照透過性が侵されてしまうからです。―たとえば、<code>unsafe</code>を同じIOアクションに適用しても毎回異なる結果を返します。そしてこれはHaskellの関数にはあってはならない振る舞いです。

まだモナドについては一般的なことはほとんどお伝えできていません。ほとんどのモナドは実際はIOとは似ていませんが、バインドとreturnに関しては同じようなコンセプトを持っています。より一般的にモナドを学びたい場合は [[Monads as containers]] の記事か [[Monads as computation]]の記事を読んでみてください。２つの記事はそれぞれモナドを異なる側面から大まかに説明しています。

- [[User:CaleGibbard|CaleGibbard]]

== さらに読みたい方に ==

* IOモナドを用いたより理解しやすいチュートリアルを見たい方は [http://haskell.org/haskellwiki/IO_inside Haskell I/O inside: Down the Rabbit's Hole] を読んでみてください
* 基本的なモナド関数の説明と例はリファレンスガイド [https://web.archive.org/web/20201109033750/members.chello.nl/hjgtuyl/tourdemonad.html A tour of the Haskell Monad functions]にあります。（Henk-Jan van Tuyl著）
* さらにこちらも参照してみてください。 [[Avoiding IO|how to avoid IO]]

[[Category:Idioms]]
[[Category:Monad]]
[[Category:Jp]]

Languages: [[Introduction to IO|en]]