# List comprehension

List comprehensions are syntactic sugar like the expression

```
import Data.Char (toUpper)
[toUpper c | c <- s]
```

where `s :: String`

is a string such as `"Hello"`

. Strings in Haskell are lists of characters; the generator `c <- s`

feeds each character of `s`

in turn to the left-hand expression `toUpper c`

, building a new list. The result of this list comprehension is `"HELLO"`

.

One may have multiple generators, separated by commas, such as

```
[(i,j) | i <- [1,2], j <- [1..4]]
```

yielding the result

```
[(1,1),(1,2),(1,3),(1,4),(2,1),(2,2),(2,3),(2,4)]
```

Note how each successive generator refines the results of the previous generator. Thus, if the second list is infinite, one will never reach the second element of the first list. For example,

```
take 10 [ (i,j) | i <- [1,2], j <- [1..]]
```

yields

```
[(1,1),(1,2),(1,3),(1,4),(1,5),(1,6),(1,7),(1,8),(1,9),(1,10)]
```

In such a situation, a nested sequence of list comprehensions may be appropriate. For example,

```
take 5 [[ (i,j) | i <- [1,2]] | j <- [1..]]
```

yields

```
[[(1,1),(2,1)], [(1,2),(2,2)], [(1,3),(2,3)], [(1,4),(2,4)], [(1,5),(2,5)]]
```

One can also provide boolean guards. For example,

```
take 10 [ (i,j) | i <- [1..], j <- [1..i-1], gcd i j == 1 ]
```

yields

```
[(2,1),(3,1),(3,2),(4,1),(4,3),(5,1),(5,2),(5,3),(5,4),(6,1)]
```

Finally, one can also make local let declarations. For example,

```
take 10 [ (i,j) | i <- [1..], let k = i*i, j <- [1..k]]
```

yields

```
[(1,1),(2,1),(2,2),(2,3),(2,4),(3,1),(3,2),(3,3),(3,4),(3,5)]
```

Here is an example of a nested sequence of list comprehensions, taken from code implementing the Sieve of Atkin:

```
[[[ poly x y
| i <- [0..], let x = m + 60*i, test x y ]
| j <- [0..], let y = n + 60*j ]
| m <- [1..60], n <- [1..60], mod (poly m n) 60 == k ]
```

The result is a list of infinite lists of infinite lists.

The specification of list comprehensions is given in The Haskell 98 Report: 3.11 List Comprehensions.

List comprehensions were generalized to monad comprehensions, which became Haskel's `do`

notation. The GHC compiler supports parallel list comprehensions as an extension; see GHC User's Guide: 7.3.4. Parallel List Comprehensions.