From HaskellWiki
Revision as of 00:32, 30 March 2007 by Conal (talk | contribs) (Applicative Functor)

Jump to: navigation, search

This page is in flux. I am preparing a new release (1.0) with some major changes.


Phooey is an arrow-based functional UI library for Haskell.

Phooey is also used in GuiTV, a library for composable interfaces and "tangible values".


GUIs are usually programmed in an unnatural style, in that implementation dependencies are inverted, relative to logical dependencies. This reversal results directly from the push (data-driven) orientation of most GUI libraries. While outputs depend on inputs from a user and semantic point of view, the push style imposes an implementation dependence of inputs on outputs.

A second drawback of the push style is that it is imperative rather than declarative. A GUI program describes actions to update a model and and view in reaction to user input. In contrast to the how-to-update style of an imperative program, a functional GUI program would express what-it-is of a model in terms of the inputs and of the view in terms of the model.

The questions of push-vs-pull and imperative-vs-declarative are related. While an imperative GUI program could certainly be written to pull (poll) values from input to model and model to view, thus eliminating the dependency inversion, I don't know how a declarative program could be written in the inverted-dependency style. (Do you?).

A important reason for using push rather than pull in a GUI implementation is that push is typically much more efficient. A simple pull implementation would either waste time recomputing an unchanging model and view (pegging your CPU for no benefit), or deal with the complexity of avoiding that recomputation. The push style computes only when inputs change. (Animation negates this advantage of push.)

Phooey ("Phunctional ooser ynterfaces") adopts the declarative style, in which outputs are expressed in terms of inputs. Under the hood, however, the implementation is push-based (data-driven). Phooey performs the dependency inversion invisibly, so that programmers may express GUIs simply and declaratively while still getting an efficient implementation. I have taken care to structure Phooey's implementation as simply as possible to make clear how this dependency inversion works (subject of paper in progress). In addition, Phooey supports dynamic input bounds, flexible layout, and mutually-referential widgets. (The last feature is currently broken.)

Phooey came out of Pajama and [1]. Pan is a re-implementation of the Pan language and compiler for function synthesis of interactive, continuous, infinite images. Pan and Pajama use a monadic style for specifying GUIs and are able to do so because they use the implementation trick of [ Compiling Embedded Languages], in which one manipulates expressions rather than values. (This trick is mostly transparent, but the illusion shows through in places.)

One example, three interfaces

As an example, below is a simple shopping list GUI. The total displayed at the bottom of the window always shows the sum of the values of the apples and bananas input sliders. When a user changes the inputs, the output updates accordingly.


Phooey presents three styles of functional GUI interfaces, structured as a monad, an arrow, and an applicative functor. Below we present code for the shopping list example in each of the three functional styles.

The examples below are all found under src/Examples/ in the phooey distribution, in the modules Monad.hs, Arrow.hs, and Monad.hs. In each case, the example is run by loading the corresponding example module into ghci and typing "runUI ui1".


Here is a definition for the GUI shown above, formulated in terms of Phooey's monadic interface.

ui1 :: UI (Source ())
ui1 = title "Shopping List" $
      do a <- title "apples"  $ islider (0,10) 3
         b <- title "bananas" $ islider (0,10) 7
         title "total" $ showDisplay (liftA2 (+) a b)

The relevant library declarations:

-- Input widget type (with initial value)
type IWidget  a =        a -> UI (Source a)
-- Output widget type
type OWidget  a = Source a -> UI (Source ())

islider     :: (Int,Int) -> IWidget Int
showDisplay :: Show a => OWidget a
title       :: String -> UI a -> UI a

The Source type is a data-driven computation. By using Source Int instead of Int for the type of a and b above, we do not have to rebuild the GUI every time an input value changes.

The down side of using source types is seen in the showDisplay line above, which requires lifting. We could partially hide the lifting behind overloadings of Num and other classes (as in Fran, Pan, and other systems). Some methods, however, do not not have sufficiently flexible types (e.g., (==)), and the illusion becomes awkward. The Arrow and Applicative interfaces hide the source types.

Before we move on to other interface styles, let's look at some refactorings. First pull out the slider minus initial value:

sl0 :: IWidget Int
sl0 = islider (0,10)

Then the titled widgets:

apples, bananas :: UI (Source Int)
apples  = title "apples"  $ sl0 3
bananas = title "bananas" $ sl0 7

total :: Num a => OWidget a
total = title "total" . showDisplay

And use them:

ui1x :: UI (Source ())
ui1x = title "Shopping List" $
       do a <- apples
          b <- bananas
          total (liftA2 (+) a b)

We can go point-free by using liftM2 and (>>=):

fruit :: UI (Source Int)
fruit = liftM2 (liftA2 (+)) apples bananas

ui1y :: UI (Source ())
ui1y = title "Shopping List" $ fruit >>= total


Using source types allows the monadic style to capture the static nature of the input GUI while giving access to a source of dynamic values. Alternatively, we can solve the problem by replacing the Monad abstraction with one that separates static and dynamic aspects. Getting that separation is the point of the Arrow abstraction, and thus Phooey provides an arrow interface as well. Moreover, the UI arrow is implemented on top of its UI monad using a simple, reusable pattern. See the Arrow module doc and its source code.

The example:

ui1 :: UI () ()
ui1 = title "Shopping List" $
      proc () -> do
	a <- title "apples"  $ islider (0,10) 3 -< ()
	b <- title "bananas" $ islider (0,10) 7 -< ()
	title "total"  showDisplay              -< a+b

Note the simplicity of a+b. Also, the slider bounds have been moved to a dynamic position, which will be discussed below.

The types of islider, showDisplay, and title as as in the monadic version, with these new definitions of input and output widget types:

type IWidget  a = a -> UI () a
type OWidget  a = UI a ()

Applicative Functor

Applicative functors provide still another approach to separating static and dynamic information. Our example:

ui1 :: UI (IO ())
ui1 = title "Shopping List" $ fruit <**> total

apples, bananas, fruit :: UI Int
apples  = title "apples"  (sl0 3)
bananas = title "bananas" (sl0 7)

fruit = liftA2 (+) apples bananas
total :: Num a => OWidget a
total = title "total" showDisplay

The UI-building functions again have the same types as before, relative to these new definitions:

type IWidget a = a -> UI a
type OWidget a = UI (a -> IO ())


  • ui1 is an IO-valued UI.
  • Output widgets are function-valued UI.
  • While apples and bananas are exactly as before, total is different, because output widgets are now function-valued.
  • Compared with the monadic version, fruit has a simpler definition, requiring only one lifting instead of two.
  • ui1 uses the reverse application operator (<**>). This reversal causes the function to appear after (below) the argument.

Dynamic Bounds

[Example ui2]


By default, UI layout follows the order of the specification, with earlier-specified components above later-specified ones. This layout may be overridden by explicit layout functions. For instance, the following definitions form variations of ui1 laid out from bottom to top and from left to right.

GUIs & code:

uiB1 = fromBottom ui1
uiL1 = fromLeft   ui1

We can also lay out a sub-assembly, as in ui3 below

ui3 = fromBottom $
      title "Shopping  List" $
      fromRight fruit >>= total

Recursive GUIs


Phooey is built on wxHaskell. Quoting from the wxHaskell home page,

wxHaskell is therefore built on top of wxWidgets -- a comprehensive C++ library that is portable across all major GUI platforms; including GTK, Windows, X11, and MacOS X.

So I expect that Phooey runs on all of these platforms. That said, I have only tried Phooey on Windows. Please give it a try and leave a message on the Talk page ("Discuss this page").

Known problems

  • Recursive examples don't work (consumes memory) in the Arrow or Applicative interface.


  • Use Javascript and HTML in place wxHaskell, and hook it up with Yhc/Javascript.