View source for OOP vs type classes

(this is just a sketch now. feel free to edit/comment it. I will include information you provided into the final version of this tutorial)


I had generally not used type classes in my application programs, but when
I'd gone to implement general purpose libraries and tried to maintain
as much flexibility as possible, it was natural to start building large
and complex class hierarchies. I tried to use my C++ experience when
doing this but I was bitten many times by the restrictions of type classes. After this experience, I think that I now have a better feeling and mind model
for type classes and I want to share it with other Haskellers -
especially ones having OOP backgrounds.

Brian Hulley provided us with the program that emulates OOP in Haskell - as
you can see, it's much larger than equivalent C++ program. An equivalent translation from Haskell to C++ should be even longer :)


== Everything is an object? ==

Most software developers are familiar with the OOP motto "everything is an object."  People accustomed to C++ classes often find the Haskell concept of type classes difficult to grasp.  Why is it so different?

C++ classes pack functions together with data, which makes it convenient to
represent and consume data.  Use of interfaces (abstract classes) allow classes to interact by contract, instead of directly manipulating the data in the other class.  There exist alternative ways in C++ to accomplish such functionality (function pointers, discriminated unions), yet these techniques are not as handy
as classes. Classes are also the primary way to hiding implementation
details. Moreover, classes represent a handy way to group related
functionality together. It's extremely useful to browse the structure of large C++ project in terms of classes instead of individual functions.

Haskell provides other solutions for these problems.

=== Type with several representations: use algebraic data type (ADT) ===

For the types with different representations, algebraic data types
(ADT) - an analog of discriminated unions - are supported:

<haskell>
data Point = FloatPoint Float Float
           | IntPoint Int Int
</haskell>

Haskell provides a very easy way to build/analyze them:

<haskell>
coord :: Point -> (Float, Float)
coord (FloatPoint x y) = (x,y)
coord (IntPoint x y) = (realToFrac x, realToFrac y)

main = do print (coord (FloatPoint 1 2))
          print (coord (IntPoint 1 2))
</haskell>

So ADTs in general are preferred in Haskell over the class-based
solution of the same problem:

<haskell>
class Point a where
    coord :: a -> (Float, Float)

data FloatPoint = FloatPoint Float Float
instance Point FloatPoint where
    coord (FloatPoint x y) = (x,y)

data IntPoint = IntPoint Int Int
instance Point IntPoint where
    coord (IntPoint x y) = (realToFrac x, realToFrac y)
</haskell>


The equivalent C++ implementation using inheritance requires much more machinery than our 5 line, ADT-based solution.  This also illustrates a Haskell benefit--it's much easier to define types/functions.  Perhaps objects are not as great as you thought before. :D


<pre>
#include <algorithm>
#include <iostream>
using namespace std;

ostream & operator<<(ostream & lhs, pair<float, float> const& rhs) {
    return lhs << "(" << rhs.first << "," << rhs.second << ")";
}

struct Point {
    virtual pair<float,float> coord() = 0;
};

struct FloatPoint : Point {
    float x, y;
    FloatPoint (float _x, float _y) : x(_x), y(_y) {}
    pair<float,float> coord() {return make_pair(x,y); }
};

struct IntPoint : Point {
    int x, y;
    IntPoint (int _x, int _y) : x(_x), y(_y) {}
    pair<float,float> coord() { return make_pair(x,y); }
};

int main () {
    cout << FloatPoint(1,2).coord();
    cout << IntPoint(1,2).coord();
    return 0;
}
</pre>

As you see, ADTs together with type inference make Haskell programs
about 2 times smaller than their C++ equivalent.


=== Packing data & functions together: use (records of) closures ===

Another typical class use-case is to pack data together with one
or more processing functions and pass this bunch to some
function. Then this function can call the aforementioned functions to implement
some functionality, not bothering how it is implemented internally.
Hopefully Haskell provides a better way: you can pass any functions as parameters to other functions directly.
Moreover, such functions can be constructed on-the-fly, capturing free variables in context, creating the so-called closures. In this way, you construct something like object on-demand and don't even need a type class:

<haskell>
do x <- newIORef 0
   proc (modifyIORef x (+1), readIORef x)
</haskell>

Here, we applied proc to two functions - one incrementing the value of a
counter and another reading its current value. Another call to proc
that uses counter with locking, might look like this:

<haskell>
do x <- newMVar 0
   proc (modifyMVar x (+1), readMVar x)
</haskell>

Here, proc may be defined as:

<haskell>
proc :: (IO (), IO Int) -> IO ()
proc (inc, read) = do { inc; inc; inc; read >>= print }
</haskell>


i.e. it receive two abstract operations whose implementation may vary
in different calls to proc and call them without any knowledge of
implementation details. The equivalent C++ code could look like this:

<pre>
class Counter {
public:
    virtual void inc()  = 0;
    virtual int  read() = 0;
};

class SimpleCounter : public Counter {
public:
    SimpleCounter()  { n = 0; }
    void inc()       { n++; }
    int  read()      { return n; }
private:
    int n;
};

void proc (Counter &c) {
    c.inc(); c.inc(); c.inc(); cout << c.read();
}
</pre>

And again, Haskell code is much simpler and more straightforward - we
don't need to declare classes, operations, their types - we just pass
to the proc implementation of operations it needs. Look at
[[IO inside#Example: returning an IO action as a result]]
and following sections to find more examples of using closures instead
of OOP classes.

=== Hiding implementation details: use module export list  ===

One more usage of OOP classes is to hide implementation details, making
internal data/functions inaccessible to class clients. Unfortunately, this
functionality is not part of type class facilities. Instead, you
should use the sole Haskell method of encapsulation, module
export list:

<haskell>
module Stack (Stack, empty, push, pop, top, isEmpty) where

newtype Stack a = Stk [a]

empty                 = Stk []
push   x (Stk xs)     = Stk (x:xs)
pop      (Stk (x:xs)) = Stk xs
top      (Stk (x:xs)) = x
isEmpty  (Stk xs)     = null xs
</haskell>

Since the constructor for the data type Stack is hidden (the export
list would say Stack(Stk) if it were exposed), outside of this module a stack can only be built from operations empty, push and pop, and
examined with top and isEmpty.


=== Grouping related functionality: use module hierarchy and Haddock markup ===

Dividing a whole program into classes and using their hierarchy to
represent entire an program structure is a great instrument for OO languages. Unfortunately, it's again impossible in Haskell. Instead,
the structure of a program is typically rendered in a module hierarchy and inside
a module - in its export list. Although Haskell doesn't provide
facilities to describe a hierarchical structure inside of a module, we have
another tool to do it - Haddock, a de-facto standard documentation tool.

<haskell>
module System.Stream.Instance (

    -- * File is a file stream
    File,
    -- ** Functions that open files
    openFile,                  -- open file in text mode
    openBinaryFile,            -- open file in binary mode
    -- ** Standard file handles
    stdin,
    stdout,
    stderr,

    -- * MemBuf is a memory buffer stream
    MemBuf,
    -- ** Functions that open MemBuf
    createMemBuf,              -- create new MemBuf
    createContiguousMemBuf,    -- create new contiguous MemBuf
    openMemBuf,                -- use memory area as MemBuf
    
) where
...
</haskell>

Here, Haddock will build documentation for a module using its export list. The export list will be divided into sections (whose
headers given with "-- *") and subsections (given with "-- **"). As
a result, module documentation reflects its structure without using
classes for this purpose.

== Type classes is a sort of templates, not classes ==

At this moment, C++ has classes and
templates. What is the difference? With a class, type
information is carried with the object itself while with templates it's
outside of the object and is part of the whole operation.

For example, if the == operation is defined as a virtual method in a class, the actual
procedure called for a==b may depend on the run-time type of 'a', but if 
the operation is defined in template, the actual procedure depends only on the instantiated template (which is determined at compile time).

Haskell's objects don't carry run-time type information. Instead,
the class constraint for a polymorphic operation is passed in as a 
"dictionary" implementing all operations of the class (there are also
other implementation techniques, but this doesn't matter). For example,

<haskell>
eqList :: (Eq a) => [a] -> [a] -> Bool
</haskell>

is translated into:

<haskell>
type EqDictionary a = (a->a->Bool, a->a->Bool)
eqList :: EqDictionary a -> [a] -> [a] -> Bool
</haskell>

where the first parameter is a "dictionary" containing the implementation of
"==" and "/=" operations for objects of type 'a'. If there are several
class constraints, a dictionary for each is passed.

If the class has base class(es), the dictionary tuple includes the base class dictionaries, so

<haskell>
class Eq a => Cmp a where
  cmp :: a -> a -> Ordering

cmpList :: (Cmp a) => [a] -> [a] -> Ordering
</haskell>

turns into:

<haskell>
type CmpDictionary a = (EqDictionary a, a -> a -> Ordering)
cmpList :: CmpDictionary a -> [a] -> [a] -> Ordering
</haskell>


Compared to C++, this is more like templates, not classes!  As with
templates, type information is part of operation, not the object! But
while C++ templates are really a form of macro-processing (like
Template Haskell) and at last end generate non-polymorphic code,
Haskell's use of dictionaries allows run-time polymorphism
(explanation of run-time polymorphism? -what is this? a form of dynamic dispatch?).

Moreover, Haskell type classes support inheritance. Run-time
polymorphism together with inheritance are often seen as OOP
distinctive points, so during long time I considered type classes as a
form of OOP implementation. But that's wrong! Haskell type classes
build on a different basis, so they are like C++ templates with added
inheritance and run-time polymorphism! And this means that the usage of
type classes is different from using classes, with its own strong and
weak points.

== Type classes vs classes ==

Here is a brief listing of differences between OOP classes and Haskell type classes

=== Type classes are like interfaces/abstract classes, not classes itself ===

There is no inheritance and data fields
(so type classes are more like interfaces than classes)....


For those more familiar with Java/C# rather than C++, type classes resemble interfaces more than the classes. In fact, the generics in those languages capture the notion of parametric polymorphism (but Haskell is a language that takes parametric polymorphism quite seriously, so you can expect a fair amount of type gymnastics when dealing with Haskell), so more precisely, type classes are like generic interfaces.

Why interface, and not class? Mostly because type classes do not implement the methods themselves, they just guarantee that the actual types that instantiate the type class will implement specific methods. So the types are like classes in Java/C#.

One added twist: type classes can decide to provide default implementation of some methods (using other methods). You would say, then they are sort of like abstract classes. Right. But at the same time, you cannot extend (inherit) multiple abstract classes, can you?

So a type class is sort of like a contract: "any type that instantiates this type class will have the following functions defined on them..." but with the added advantage that you have type parameters built-in, so:

<haskell>
class Eq a where
  (==) :: a -> a -> Bool
  (/=) :: a -> a -> Bool
  -- let's just implement one function in terms of the other
  x /= y = not (x == y) 
</haskell>

is, in a Java-like language:

'''interface''' Eq<A> {
   '''boolean''' equal(A that);
   '''boolean''' notEqual(A that) { 
      ''// default, can be overriden''
      '''return''' !equal(that); 
   } 
}

And the "instance TypeClass ParticularInstance where ..." definition means "ParticularInstance implements TypeClass { ... }", now, multiple parameter type classes, of course, cannot be interpreted this way.


=== Type can appear at any place in function signature ===
Type can appear at any place in function signature: be any
parameter, inside parameter, in a list (possibly empty), or in a result

<haskell>
class C a where
    f :: a -> Int
    g :: Int -> a -> Int
    h :: Int -> (Int,a) -> Int
    i :: [a] -> Int
    j :: Int -> a
    new :: a
</haskell>

It's even possible to define instance-specific constants (look at 'new').

If function value is instance-specific, OOP programmer will use
"static" method while with type classes you need to use fake
parameter:

<haskell>
class FixedSize a where
  sizeof :: a -> Int
instance FixedSize Int8 where
  sizeof _ = 1
instance FixedSize Int16 where
  sizeof _ = 2

main = do print (sizeof (undefined::Int8))
          print (sizeof (undefined::Int16))
</haskell>


=== Inheritance between interfaces ===
Inheritance between interfaces (in "class" declaration) means
inclusion of base class dictionaries in dictionary of subclass:

<haskell>
class (Show s, Monad m s) => Stream m s where
    sClose :: s -> m ()
</haskell>

means

<haskell>
type StreamDictionary m s = (ShowDictionary s, MonadDictionary m s, s->m())
</haskell>

There is upcasting mechanism, it just extracts dictionary of a base
class from a dictionary tuple, so you can run a function that requires
base class from a function that requires subclass:

<haskell>
f :: (Stream m s) =>  s -> m String
show ::  (Show s) =>  s -> String
f s = return (show s)
</haskell>

But downcasting is absolutely impossible - there is no way to get
subclass dictionary from a superclass one



=== Inheritance between instances ===
Inheritance between instances (in "instance" declaration) means
that operations of some class can be executed via operations of other
class, i.e. such declaration describe a way to compute dictionary of
inherited class via functions from dictionary of base class:

<haskell>
class Eq a where
  (==) :: a -> a -> Bool
class Cmp a where
  cmp :: a -> a -> Ordering
instance (Cmp a) => Eq a where
  a==b  =  cmp a b == EQ
</haskell>

creates the following function:

<haskell>
cmpDict2EqDict :: CmpDictionary a -> EqDictionary a
cmpDict2EqDict (cmp) = (\a b -> cmp a b == EQ)
</haskell>

This results in that any function that receives dictionary for Cmp class
can call functions that require dictionary of Eq class


=== Downcasting is a mission impossible ===

Selection between instances is done at compile-time, based only on
information present at the moment. So don't expect that more concrete
instance will be selected just because you passed this concrete
datatype to the function which accepts some general class:

<haskell>
class Foo a where
  foo :: a -> String

instance (Num a) => Foo a where
  foo _ = "Num"

instance Foo Int where
  foo _ = "int"

f :: (Num a) =>  a -> String
f = foo

main = do print (foo (1::Int))
          print (f (1::Int))
</haskell>

Here, the first call will return "int", but second - only "Num".
this can be easily justified by using dictionary-based translation
as described above. After you've passed data to polymorphic procedure
it's type is completely lost, there is only dictionary information, so
instance for Int can't be applied. The only way to construct Foo
dictionary is by calculating it from Num dictionary using the first
instance.

:<i>Remark: This isn't even a legal program unless you use the <hask>IncoherentInstances</hask> language extension. The error message:</i>

<haskell>
 Overlapping instances for Foo a
  arising from a use of `foo' at /tmp/I.hs:17:4-6
 Matching instances:
   instance [overlap ok] (Num a) => Foo a
     -- Defined at /tmp/I.hs:10:9-24
   instance [overlap ok] Foo Int -- Defined at /tmp/I.hs:13:9-15
 (The choice depends on the instantiation of `a'
 To pick the first instance above, use -XIncoherentInstances 
 when compiling the other instance declarations)
</haskell>
:<i>Details: [http://haskell.org/ghc/docs/latest/html/users_guide/type-class-extensions.html#instance-overlap GHC User's Guide]</i>

=== There is only one dictionary per function call ===
For "eqList :: (Eq a) => [a] -> [a] -> Bool" types of all elements
in list must be the same, and types of both arguments must be the same
too - there is only one dictionary and it know how to handle variables
of only one concrete type!

=== Existential variables is more like OOP objects ===
Existential variables pack dictionary together with variable (looks
very like the object concept!) so it's possible to create polymorphic
containers (i.e. holding variables of different types). But
downcasting is still impossible. Also, existentials still don't allow
to mix variables of different types in a call to some polymorhic operation
(their personal dictionaries still built for variables of one concrete type):

<haskell>
data HasCmp = forall a. Cmp a => HasCmp a

sorted :: [HasCmp] -> Ordering

sorted []  = True
sorted [_] = True
sorted (HasCmp a : HasCmp b : xs)  =  a<=b && sorted (b:xs)
</haskell>

This code will not work - a<=b can use nor 'a' neither 'b' dictionary.
Even if orderings for apples and penguins are defined, we still don't have
a method to compare penguins to apples!


== Other opinions ==

=== OO class always corresponds to a haskell class + a related haskell existential (John Meacham) ===

 > Roughly Haskell type classes correspond to parameterized abstract
 > classes in C++ (i.e. class templates with virtual functions 
 > representing the operations).  Instance declarations correspond to
 > derivation and implementations of those parameterized classes.

There is a major difference though, in C++ (or java, or sather, or c#,
etc.) the dictionary is always attached to the value, the actual class
data type you pass around. In Haskell, the dictionary is passed
separately and the appropriate one is inferred by the type system. C++
doesn't infer, it just assumes everything will be carrying around its
dictionary with it.

This makes Haskell classes significantly more powerful in many ways.

<haskell>
class Num a where
   (+) :: a -> a -> a
</haskell>

is impossible to express in OO classes: since both arguments to +
necessarily carry their dictionaries with them, there is no way to
statically guarantee they have the same one. Haskell will pass a single
dictionary that is shared by both types so it can handle this just fine.

In haskell you can do

<haskell>
class Monoid a where
        mempty :: a
</haskell>

In OOP, this cannot be done because where does the dictionary come from?
Since dictionaries are always attached to a concrete class, every method
must take at least one argument of the class type (in fact, exactly one,
as I'll show below). In Haskell again, this is not a problem since the
dictionary is passed in by the consumer of 'mempty' - mempty need not
conjure one out of thin air.

In fact, OO classes can only express single parameter type classes where
the type argument appears exactly once in strictly covariant position.
In particular, it is pretty much always the first argument and often
(but not always) named 'self' or 'this'.

<haskell>
class HasSize a where
        getSize :: a -> Int
</haskell>

can be expressed in OO, 'a' appears only once, as its first argument.

Now, another thing OO classes can do is they give you the ability to
create existential collections (?) of objects. As in, you can have a
list of things that have a size. In Haskell, the ability to do this is
independent of the class (which is why Haskell classes can be more
powerful) and is appropriately named existential types.

<haskell>
data Sized = exists a . HasSize a => Sized a 
</haskell>

What does this give you? You can now create a list of things that have a
size  [Sized] yay!

And you can declare an instance for Sized, so you can use all your
methods on it.

<haskell>
instance HasSize Sized where
        getSize (Sized a) = getSize a
</haskell>

An existential, like Sized, is a value that is passed around with its
dictionary in tow, as in, it is an OO class! I think this is where
people get confused when comparing OO classes to Haskell classes. _There
is no way to do so without bringing existentials into play_. OO classes
are inherently existential in nature.

So, an OO abstract class declaration declares the equivalent of 3 things
in Haskell: a class to establish the methods, an existential type to
carry the values about, and an instance of the class for the existential
type.

An OO concrete class declares all of the above plus a data declaration
for some concrete representation.

OO classes can be perfectly (even down to the runtime representation!)
emulated in Haskell, but not vice versa. Since OO languages tie class
declarations to existentials, they are limited to only the intersection
of their capabilities, because Haskell has separate concepts for them;
each is independently much much more powerful.

<haskell>
data CanApply = exists a b . CanApply (a -> b) a (b -> a)
</haskell>

is an example of something that cannot be expressed in OO, existentials
are limited to having exactly a single value since they are tied to a
single dictionary.

<haskell>
class Num a where
   (+) :: a -> a -> a
   zero :: a
   negate :: a -> a
</haskell>

cannot be expressed in OO, because there is no way to pass in the same
dicionary for two elements, or for a returning value to conjure up a
dictionary out of thin air. (If you are not convinced, try writing a
'Number' existential and making it an instance of Num and it will be
clear why it is not possible.)

negate is an interesting one - there is no technical reason it cannot be
implemented in OO languages, but none seem to actually support it.

So, when comparing, remember an OO class always corresponds to a Haskell
class + a related Haskell existential.

Incidentally, an extension I am working on is to allow

<haskell>
data Sized = exists a . HasSize a => Sized a 
        deriving(HasSize)
</haskell>

which would have the obvious interpretation. Obviously it would only work
under the same limitations as OO classes have, but it would be a simple
way for haskell programs to declare OO style classes if they so choose.

(Actually, it is still signifigantly more powerful than OO classes since
you can derive many instances, and even declare your own for classes
that don't meet the OO constraints. Also, your single class argument need
not appear as the first one. It can appear in any strictly covariant
position, and it can occur as often as you want in contravariant ones!)

=== Type classes correspond to parameterized abstract classes (Gabriel Dos Reis) ===

 | > Roughly Haskell type classes correspond to parameterized abstract
 | > classes in C++ (i.e. class templates with virtual functions 
 | > representing the operations).  Instance declarations correspond to
 | > derivation and implementations of those parameterized classes.
 | 
 | There is a major difference though, in C++ (or java, or sather, or c#,
 | etc..) the dictionary is always attached to the value, the actual class
 | data type you pass around.

I suspect that most of the confusion come from the fact that people
believe just because virtual functions are attached to objects, 
they cannot attach them to operations outside classes.  That, to my
surprise, hints at a deeper misappreciation of both type classes and
so-called "OO" technology.  Type classes are more OO than one might
realize. 

The dictionary can be attached to the operations (not just to the values) by
using objects local to functions (which sort of matierialize the
dictionary).  Consider

    // Abstract class for a collection of classes that implement
    // the "Num" mathematical structure
    template<typename T>
      struct Num {
          virtual T add(T, T) const = 0;
      };

    // Every type must specialize this class template to assert
    // membership to the "Num" structure.  
    template<typename T> struct Num_instance;

    // The operation "+" is defined for any type that belongs to "Num".
    // Notice, membership is asserted aby specializing Num_instance<>.
    template<typename T>
      T operator+(T lhs, T rhs)
      {
         const Num_instance<T> instance;  
         return instance.add(lhs, rhs);
      }

    // "Foo" is in "Num"
    struct Num_instance<Foo> : Num<Foo> {
       Foo add(Foo a, Foo b) const { ... }
    };


The key here is in the definition of operator+ which is just a formal
name for the real operation done by instance.add().

I appreciate that inferring and building the dictionary (represented
here by the "instance" local to operator+<T>) is done automatically by
the Haskell type system.
That is  one of the reasons why the type class notation is a nice sugar.
However, that should not distract from its deerper OO semantics.
    

[...]

 | in haskell you can do
 | 
 | class Monoid a where
 |         mempty :: a
 | 
 | in OOP, this cannot be done because where does the dicionary come from?

See above.  I believe a key in my suggestion was "parameterized
abstract classes", not just "abstract classes".



== Haskell emulation of OOP inheritance with record extension ==

Brian Hulley provided us the code that shows how OOP inheritance can be
emulated in Haskell. His translation method supports data fields
inheritance, although doesn't support downcasting.

 > although i mentioned not only pluses but also drawbacks of type
 > classes: lack of record extension mechanisms (such at that implemented
 > in O'Haskell) and therefore inability to reuse operation
 > implementation in an derived data type...

You can reuse ops in a derived data type but it involves a tremendous amount 
of boilerplate. Essentially, you just use the type classes to simulate 
extendable records by having a method in each class that accesses the 
fixed-length record corresponding to that particular C++ class.

Here is an example (apologies for the length!) which shows a super class 
function being overridden in a derived class and a derived class method 
(B::Extra) making use of something implemented in the super class:

<haskell>
module Main where

{-  Haskell translation of the following C++

    class A {
    public:
        String s;
        Int i;

        A(String s, Int i) s(s), i(i){}

        virtual void Display(){
            printf("A %s %d\n", s.c_str(), i);
        }

        virtual Int Reuse(){
            return i * 100;
        }
    };


    class B: public A{
    public:
        Char c;

        B(String s, Int i, Char c) : A(s, i), c(c){}

        virtual void Display(){
            printf("B %s %d %c", s.c_str(), i, c);
        }

        virtual void Extra(){
            printf("B Extra %d\n", Reuse());
        }

    };

-}

data A = A
                { _A_s :: String
                , _A_i :: Int
                }

-- This could do arg checking etc
constructA :: String -> Int -> A
constructA = A


class ClassA a where
    getA :: a -> A

    display :: a -> IO ()
    display a = do
        let
            A{_A_s = s, _A_i = i} = getA a
        putStrLn $ "A " ++ s ++ show i

    reuse :: a -> Int
    reuse a = _A_i (getA a) * 100


data WrapA = forall a. ClassA a => WrapA a

instance ClassA WrapA where
    getA (WrapA a) = getA a
    display (WrapA a) = display a
    reuse (WrapA a) = reuse a

instance ClassA A where
    getA = id


data B = B { _B_A :: A, _B_c :: Char }


constructB :: String -> Int -> Char -> B
constructB s i c = B {_B_A = constructA s i, _B_c = c}

class ClassA b => ClassB b where
    getB :: b -> B

    extra :: b -> IO ()
    extra b = do
        putStrLn $ "B Extra " ++ show (reuse b)

data WrapB = forall b. ClassB b => WrapB b

instance ClassB WrapB where
    getB (WrapB b) = getB b
    extra (WrapB b) = extra b

instance ClassA WrapB where
    getA (WrapB b) = getA b
    display (WrapB b) = display b
    reuse (WrapB b) = reuse b

instance ClassB B where
    getB = id

instance ClassA B where
    getA = _B_A

    -- override the base class version
    display b = putStrLn $
                "B " ++ _A_s (getA b)
                ++ show (_A_i (getA b))
                ++ [_B_c (getB b)]


main :: IO ()
main = do
    let
        a = constructA "a" 0
        b = constructB "b" 1 '*'

        col = [WrapA a, WrapA b]

    mapM_ display col
    putStrLn ""
    mapM_ (putStrLn . show . reuse) col
    putStrLn ""
    extra b

{- Output:

   > ghc -fglasgow-exts --make Main
   > main
   A a0
   B b1*

   0
   100

   B Extra 100

   >
-}
</haskell>

(If the "caseless underscore" Haskell' ticket is accepted the leading 
underscores would have to be replaced by something like "_f" ie _A_s ---> 
_fA_s etc)

== Type class system extensions ==

Brief list of extensions, their abbreviated names and compatibility level

* Constructor classes (Haskell'98)
* MPTC: multi-parameter type classes (Hugs/GHC extension)
* FD: functional dependencies (Hugs/GHC extension)
* AT: associated types (GHC 6.6 only)
* Overlapped, undecidable and incoherent instances (Hugs/GHC extension)


== Literature ==

The paper that at first time introduced type classes and their implementation
using dictionaries was Philip Wadler and Stephen Blott "How to make ad-hoc polymorphism less ad-hoc" (http://homepages.inf.ed.ac.uk/wadler/papers/class/class.ps.gz)

You can find more papers on the [http://haskell.org/haskellwiki/Research_papers/Type_systems#Type_classes Type classes] page.

I thanks Ralf Lammel and Klaus Ostermann for their paper
"Software Extension and Integration with Type Classes" (http://homepages.cwi.nl/~ralf/gpce06/) which prompts me to start thinking about differences between OOP and type classes instead of their similarities

[[Category:Tutorials]]
[[Category:Pages under construction]]