# Difference between revisions of "Avoiding partial functions"

(→init, last: import forcePair) |
(categories: style, idioms) |
||

Line 121: | Line 121: | ||

[[Category:Tutorials]] |
[[Category:Tutorials]] |
||

+ | [[Category:Style]] |
||

+ | [[Category:Idioms]] |

## Revision as of 09:29, 7 June 2012

There are several partial functions in the Haskell standard library. If you use them, you always risk to end up with an undefined. In this article we give some hints how to avoid them, leading to code that you can be more confident about.

For a partial function f the general pattern is: Whereever we write "check whether x is in the domain of f before computing f x", we replace it by combination of check and computation of f.

## fromJust

You should replace

```
if isNothing mx
then g
else h (fromJust mx)
```

by

```
case mx of
Nothing -> g
Just x -> h x
```

## head, tail

You should replace

```
if null xs
then g
else h (head xs) (tail xs)
```

by

```
case xs of
[] -> g
y:ys -> h y ys
```

## init, last

You may replace

```
if null xs
then g
else h (init xs) (last xs)
```

by

```
case xs of
[] -> g
y:ys -> uncurry h $ viewRTotal y ys
viewRTotal :: a -> [a] -> ([a], a)
viewRTotal x xs =
forcePair $
foldr
(\x0 go y -> case go y of ~(zs,z) -> (x0:zs,z))
(\y -> ([],y))
xs x
forcePair :: (a,b) -> (a,b)
forcePair ~(a,b) = (a,b)
```

You might define `viewRTotal`

in a `Utility`

module.
You can import `forcePair`

from utility-ht.

## (!!)

You should replace

```
if k < length xs
then xs!!k
else y
```

by

```
case drop k xs of
x:_ -> x
[] -> y
```

This is also more lazy, since for computation of `length`

you have to visit every element of the list.

## irrefutable pattern match on (:)

You should replace

```
if k < length xs
then let (prefix,x:suffix) = splitAt k xs
in g prefix x suffix
else y
```

by

```
case splitAt k xs of
(prefix,x:suffix) -> g prefix x suffix
(_,[]) -> y
```

## minimum

The function `isLowerLimit`

checks if a number is a lower limit to a sequence.
You may implement it with the partial function `minimum`

.

```
isLowerLimit :: Ord a => a -> [a] -> Bool
isLowerLimit x ys = x <= minimum ys
```

It fails if `ys`

is empty or infinite.

You should replace it by

```
isLowerLimit x = all (x<=)
```

This definition terminates for infinite lists, if `x`

is not a lower limit. It aborts immediately if an element is found which is below `x`

.
Thus it is also faster for finite lists.
Even more: It also works for empty lists.