Constructor

Constructor can mean:

• Type constructor
• Data constructor (or value constructor)

A data declaration introduces a type constructor and some data constructors for this type constructor.

Type constructor

A type constructor may have zero or more arguments, if it has zero arguments it is called a nullary type constructor (or simply a type). An example of a nullary type constructor Bool with two nullary data constructors True and False

data Bool = True | False

An example of a unary type constructor

Tree

data Tree a = Tip | Node a (Tree a) (Tree a)

illustrates how to define a data type with type constructors (and data constructors at the same time). The type constructor is named Tree, but a tree of what? Of any specific type a, be it Integer, Maybe String, or even Tree b, in which case it will be a tree of tree of b. The data type is polymorphic (and a is a type variable that is to be substituted by a specific type). So when used, the values will have types like Tree Int or Tree (Tree Boolean).

Data constructor

A data constructor (or value constructor) can have zero or more arguments where a data constructor taking zero arguments is called a nullary data constructor or simply a constant. They group values together and tag alternatives in an algebraic data type. E.g., the Tree a type from above

data Tree a = Tip | Node a (Tree a) (Tree a)

has two data constructors, Tip and Node. Any value that belongs to the type Tree a (again, we leave the type parameter unspecified) will be a constructed by either Tip or Node. Tip is a constructor that groups no value, i.e, it's a nullary constructor. There is only one value, conveniently denoted Tip that has this constructor. So, nullary constructors contain no data apart from their name! For example, the Bool data type is defined as

data Bool = True | False

and for all practical purposes you can just think of True and False as constants belonging to a type. On the other hand, Node contains other data. The types of those data are its parameters. The first one has type a, so it's just a value of the parameter type a. This one is the value the tree node holds in it. The remaining two are the branches. Each of them have type Tree a, naturally.

Data constructors as first class values

Data constructors are first class values in Haskell and actually have a type. For instance, the type of the Left constructor of the Either data type is:

Left :: a -> Either a b

As first class values, they may be passed to functions, held in a list, be data elements of other algebraic data types and so forth.

Data constructors are not types

As discussed above, they denote values. It is illegal to write Node a (Node a) (Node a) there, because the type is Tree, not Node.

Deconstructing data constructors

All a data constructor does is holding values together. But you want to separate them if you want to use them. This is done via pattern matching,

depth Tip          = 0
depth (Node _ l r) = 1 + max (depth l) (depth r)

So, the depth of a tip is zero. The depth of a node depends on its branches, but not its content. See how the constructor in the left hand side names its parts? we don't need the content so we don't name it (using _). The left branch is named l, the right r, allowing us to use these values in the right hand side.

Notes and tips

• You can declare a constructor (for both type and data) to be an infix operator, and this can make your code a lot more readable. However, for alphanumeric names, the names of both the type constructor and the data constructor(s) must start with an uppercase letter.
• Tuples are a built in feature of the syntax but are plain old algebraic data types! They have only one constructor though. Having the same name as their types (don't freak out, it's just a matter of convenience, as the type constructors and the data constructors have separate namespaces). So, (4, True) is really a value of the form (,) 4 True having the type (,) Int Bool, which, too, is written conveniently as (Int, Bool) to make it more readable. Incidentally, the empty tuple type () with its only value () is used throughout, and is called unit.
• You can, in fact, name the values grouped together, using the record syntax,

  data Person = Person { name :: String, age :: Int, address :: String }

  so that for a person p, you can say age p to select his/her age, without resorting to pattern matching.
• Sometimes you need a little editing or checking when constructing your data. If you do, check smart constructors.
• Sometimes you do not want the user of your library to group arbitrary values together. This is achieved by hiding your constructor (not mentioning it in the export list of the module), creating an abstract data type as a result. Along with smart constructors mentioned above, one can achieve encapsulation.
• Type constructors are used to denote the types of functions, e.g.,
  

  depth :: Tree a -> Int

  Data or value constructors are used to pattern match, e.g.,
  

  depth (Node _ l r) = ...

• If you want to dig deeper into the Haskell type system: a data or value constructor has a type, e.g., Node 3 Tip Tip has type Tree Int; a type of a type constructor itself is called kind.

References

• Programming in Standard ML: Chapter 10 (Concrete Data Types)