Monad

From HaskellWiki

Hint: if you're just looking for an introduction to monads, see Merely monadic or one of the other monad tutorials.

Monad class (base)
import Control.Monad

The Monad class[edit]

Monads can be viewed as a standard programming interface to various data or control structures, which is captured by Haskell's Monad class. All the common monads are members of it: 

class Monad m where
  (>>=)  :: m a -> (  a -> m b) -> m b
  (>>)   :: m a ->  m b         -> m b
  return ::   a                 -> m a

In addition to implementing the class functions, all instances of Monad should satisfy the following equations, or monad laws: 

return a >>= k                  =  k a
m        >>= return             =  m
m        >>= (\x -> k x >>= h)  =  (m >>= k) >>= h

For more information, including an intuitive explanation of why the monad laws should be satisfied, see Monad laws.

As of GHC 7.10, the Applicative typeclass is a superclass of Monad, and the Functor typeclass is a superclass of Applicative. This means that all monads are applicatives, all applicatives are functors, and therefore all monads are also functors. For more information, see the Functor hierarchy proposal.

If the Monad definitions are preferred, Functor and Applicative instances can be defined from them with: 

fmap fab ma  =  do { a <- ma ; return (fab a) }
            --  ma >>= (return . fab)
pure a       =  do { return a }
            --  return a
mfab <*> ma  =  do { fab <- mfab ; a <- ma ; return (fab a) }
            --  mfab >>= (\ fab -> ma >>= (return . fab)) 
            --  mfab `ap` ma

although the recommended order is to define return as pure if the two would otherwise end up being the same.

Common monads[edit]

These include:

  • Representing failure using Maybe monad
  • Nondeterminism using List monad to represent carrying multiple values
  • State using State monad
  • Read-only environment using Reader monad
  • I/O using IO monad

do-notation[edit]

In order to improve the look of code that uses monads, Haskell provides a special form of syntactic sugar called do-notation. For example, the following expression: 

thing1 >>= (\x -> func1 x >>= (\y -> thing2 
       >>= (\_ -> func2 y >>= (\z -> return z))))

which can be written more clearly by breaking it into several lines and omitting parentheses: 

thing1  >>= \x ->
func1 x >>= \y ->
thing2  >>= \_ ->
func2 y >>= \z ->
return z

can also be written using do-notation: 

do {
  x <- thing1 ;
  y <- func1 x ;
  thing2 ;
  z <- func2 y ;
  return z
  }

(the curly braces and the semicolons are optional when the indentation rules are observed).

Code written using do-notation is transformed by the compiler to ordinary expressions that use the functions from the Monad class (i.e. the two varieties of bind: (>>=) and (>>)).

When using do-notation and a monad like State or IO, programs in Haskell look very much like programs written in an imperative language as each line contains a statement that can change the simulated global state of the program and optionally binds a (local) variable that can be used by the statements later in the code block.

It is possible to intermix the do-notation with regular notation.

More on do-notation can be found in a section of Monads as computation and in other tutorials.

Commutative monads[edit]

For monads which are commutative the order of actions makes no difference (i.e. they commute), so the following code: 

do
  a <- actA
  b <- actB
  m a b

is the same as: 

do
  b <- actB
  a <- actA
  m a b

Examples of commutative monads include:

  • Reader monad
  • Maybe monad

Monad tutorials[edit]

Monads are known for being quite confusing to many people, so there are plenty of tutorials specifically related to monads. Each takes a different approach to monads, and hopefully everyone will find something useful.

See the Monad tutorials timeline for a comprehensive list of monad tutorials.

Monad reference guides[edit]

An explanation of the basic Monad functions, with examples, can be found in the reference guide A tour of the Haskell Monad functions by Henk-Jan van Tuyl.

Monad research[edit]

A collection of research papers about monads.

Monads in other languages[edit]

Implementations of monads in other languages.

Unfinished:

And possibly there exists:

  • Standard ML (via modules?)

(If you know of other implementations, please add them here.)

Interesting monads[edit]

A list of monads for various evaluation strategies and games:

There are many more interesting instances of the monad abstraction out there. Please add them as you come across each species.

Fun[edit]

See also[edit]
Retrieved from "https://wiki.haskell.org/index.php?title=Monad&oldid=65405"