Difference between revisions of "Roll your own IRC bot"

From HaskellWiki
Jump to: navigation, search
(Update code)
m (Where to now?: Remove dead link)
 
(7 intermediate revisions by the same user not shown)
Line 5: Line 5:
 
programmer. Our goal is to write a concise, robust and elegant
 
programmer. Our goal is to write a concise, robust and elegant
 
[http://haskell.org/haskellwiki/IRC_channel IRC] bot in Haskell.
 
[http://haskell.org/haskellwiki/IRC_channel IRC] bot in Haskell.
  +
  +
A packaged-up version of the code is [https://github.com/Lysxia/roll-your-own-irc-bot available on GitHub].
   
 
== Getting started ==
 
== Getting started ==
   
 
You'll need a reasonably recent version of [http://haskell.org/ghc GHC]. Our first step is to get on the
 
You'll need a reasonably recent version of [http://haskell.org/ghc GHC]. Our first step is to get on the
network. So let's start by importing the ''network'' package, and the
+
network. So let's start by importing modules from the standard library and the ''network'' package, and defining a server to connect to.
standard IO library and defining a server to connect to.
 
   
 
<haskell>
 
<haskell>
  +
-- File 1.hs
  +
 
import System.IO -- base
 
import System.IO -- base
 
import qualified Network.Socket as N -- network
 
import qualified Network.Socket as N -- network
   
  +
-- Configuration options
 
myServer = "irc.freenode.org" :: String
 
myServer = "irc.freenode.org" :: String
 
myPort = 6667 :: N.PortNumber
 
myPort = 6667 :: N.PortNumber
   
  +
-- Toplevel program
 
main :: IO ()
 
main :: IO ()
 
main = do
 
main = do
 
h <- connectTo myServer myPort
 
h <- connectTo myServer myPort
hSetBuffering stdout NoBuffering
 
 
t <- hGetContents h
 
t <- hGetContents h
  +
hSetBuffering stdout NoBuffering
 
print t
 
print t
   
  +
-- Connect to a server given its name and port number
 
connectTo :: N.HostName -> N.PortNumber -> IO Handle
 
connectTo :: N.HostName -> N.PortNumber -> IO Handle
 
connectTo host port = do
 
connectTo host port = do
Line 67: Line 74:
   
 
<haskell>
 
<haskell>
  +
-- File 2.hs
  +
 
import System.IO -- base
 
import System.IO -- base
 
import qualified Network.Socket as N -- network
 
import qualified Network.Socket as N -- network
   
  +
-- Configuration options
 
myServer = "irc.freenode.org" :: String
 
myServer = "irc.freenode.org" :: String
 
myPort = 6667 :: N.PortNumber
 
myPort = 6667 :: N.PortNumber
Line 75: Line 85:
 
myNick = "tutbot" :: String
 
myNick = "tutbot" :: String
   
  +
-- Toplevel program
 
main :: IO ()
 
main :: IO ()
 
main = do
 
main = do
Line 83: Line 94:
 
listen h
 
listen h
   
  +
-- Connect to a server given its name and port number
 
connectTo :: N.HostName -> N.PortNumber -> IO Handle
 
connectTo :: N.HostName -> N.PortNumber -> IO Handle
 
connectTo host port = do
 
connectTo host port = do
Line 90: Line 102:
 
N.socketToHandle sock ReadWriteMode
 
N.socketToHandle sock ReadWriteMode
   
  +
-- Send a message to a handle
 
write :: Handle -> String -> String -> IO ()
 
write :: Handle -> String -> String -> IO ()
 
write h cmd args = do
 
write h cmd args = do
Line 96: Line 109:
 
putStr ("> " ++ msg) -- Show sent message on the command line
 
putStr ("> " ++ msg) -- Show sent message on the command line
   
  +
-- Process each line from the server
 
listen :: Handle -> IO ()
 
listen :: Handle -> IO ()
 
listen h = forever $ do
 
listen h = forever $ do
Line 108: Line 122:
   
 
<haskell>
 
<haskell>
  +
-- Send a message to a handle
 
write :: Handle -> String -> String -> IO ()
 
write :: Handle -> String -> String -> IO ()
 
write h cmd args = do
 
write h cmd args = do
Line 120: Line 135:
   
 
<haskell>
 
<haskell>
  +
-- Process each line from the server
 
listen :: Handle -> IO ()
 
listen :: Handle -> IO ()
 
listen h = forever $ do
 
listen h = forever $ do
Line 129: Line 145:
 
</haskell>
 
</haskell>
   
This function takes a Handle argument, and sits in an infinite loop reading lines of text from the network and printing them. We take advantage of two powerful features; lazy evaluation and higher order functions to roll our own loop control structure, <code>forever</code>, as a normal function! <code>forever</code> takes a chunk of code as an argument, evaluates it and recurses - an infinite loop function. It is very common to roll our own control structures in Haskell this way, using higher order functions. No need to add new syntax to the language, lisp-like macros or meta programming - you just write a normal function to implement whatever control flow you wish. We can also avoid <code>do</code>-notation, and directly write: <code>forever a = a >> forever a</code>. Note that <code>forever</code> can also be found in the standard library ''base'', in the module [https://hackage.haskell.org/package/base-4.12.0.0/docs/Control-Monad.html#v:forever <code>Control.Monad</code>] (with a more general type).
+
This function takes a <code>Handle</code> argument, and sits in an infinite loop reading lines of text from the network and printing them. We take advantage of two powerful features; lazy evaluation and higher order functions to roll our own loop control structure, <code>forever</code>, as a normal function! <code>forever</code> takes a chunk of code as an argument, evaluates it and recurses - an infinite loop function. It is very common to roll our own control structures in Haskell this way, using higher order functions. No need to add new syntax to the language, lisp-like macros or meta programming - you just write a normal function to implement whatever control flow you wish. We can also avoid <code>do</code>-notation, and directly write: <code>forever a = a >> forever a</code>. Note that <code>forever</code> can also be found in the standard library ''base'', in the module [https://hackage.haskell.org/package/base-4.12.0.0/docs/Control-Monad.html#v:forever <code>Control.Monad</code>] (with a more general type).
   
 
Let's run this thing:
 
Let's run this thing:
Line 172: Line 188:
   
 
<haskell>
 
<haskell>
  +
-- Connect to a server given its name and port number
 
listen :: Handle -> IO ()
 
listen :: Handle -> IO ()
 
listen h = forever $ do
 
listen h = forever $ do
Line 205: Line 222:
 
 
 
<haskell>
 
<haskell>
  +
-- Dispatch a command
 
eval :: Handle -> String -> IO ()
 
eval :: Handle -> String -> IO ()
 
eval h "!quit" = write h "QUIT" ":Exiting" >> exitSuccess
 
eval h "!quit" = write h "QUIT" ":Exiting" >> exitSuccess
Line 211: Line 229:
 
</haskell>
 
</haskell>
 
 
So, if the single string <code>"!quit"</code> is received, we inform the server and exit the program. If a string beginning with <code>"!id"</code> appears, we echo any argument string back to the server (the command <code>"!id"</code> is thus named because <code>id</code> is the Haskell identity function, which just returns its argument). Finally, if no other matches occur, we do nothing.
+
So, if the single string <code>"!quit"</code> is received, we inform the server and exit the program. If a string beginning with <code>"!id "</code> appears, we echo any argument string back to the server (the command is named after the identity function <code>id</code>, which just returns its argument). Finally, if no other matches occur, we do nothing.
   
 
We add the <code>privmsg</code> function - a useful wrapper over <code>write</code> for sending <code>PRIVMSG</code> lines to the server.
 
We add the <code>privmsg</code> function - a useful wrapper over <code>write</code> for sending <code>PRIVMSG</code> lines to the server.
   
 
<haskell>
 
<haskell>
  +
-- Send a privmsg to the channel
 
privmsg :: Handle -> String -> IO ()
 
privmsg :: Handle -> String -> IO ()
 
privmsg h s = write h "PRIVMSG" (chan ++ " :" ++ s)
 
privmsg h s = write h "PRIVMSG" (chan ++ " :" ++ s)
Line 240: Line 259:
 
So let's define a small reader monad:
 
So let's define a small reader monad:
 
<haskell>
 
<haskell>
  +
-- The 'Net' monad, a wrapper over IO, carrying the bot's immutable state.
 
data Bot = Bot { botSocket :: Handle }
 
data Bot = Bot { botSocket :: Handle }
 
 
type Net = ReaderT Bot IO
 
type Net = ReaderT Bot IO
 
</haskell>
 
</haskell>
Line 258: Line 277:
   
 
<haskell>
 
<haskell>
  +
-- Toplevel program
 
main :: IO ()
 
main :: IO ()
 
main = bracket connect disconnect loop
 
main = bracket connect disconnect loop
Line 289: Line 309:
   
 
<haskell>
 
<haskell>
  +
-- File 4.hs
  +
 
import Control.Exception -- base
 
import Control.Exception -- base
 
import Control.Monad.IO.Class --
 
import Control.Monad.IO.Class --
Line 297: Line 319:
 
import Control.Monad.Trans.Reader -- transformers
 
import Control.Monad.Trans.Reader -- transformers
   
  +
-- Configuration options
 
myServer = "irc.freenode.org" :: String
 
myServer = "irc.freenode.org" :: String
 
myPort = 6667 :: N.PortNumber
 
myPort = 6667 :: N.PortNumber
Line 311: Line 334:
 
-- The 'Net' monad, a wrapper over IO, carrying the bot's immutable state.
 
-- The 'Net' monad, a wrapper over IO, carrying the bot's immutable state.
 
data Bot = Bot { botSocket :: Handle }
 
data Bot = Bot { botSocket :: Handle }
 
 
type Net = ReaderT Bot IO
 
type Net = ReaderT Bot IO
   
Line 342: Line 364:
 
listen
 
listen
   
-- Send a message out to the server we're currently connected to
+
-- Send a message to the server we're currently connected to
 
write :: String -> String -> Net ()
 
write :: String -> String -> Net ()
 
write cmd args = do
 
write cmd args = do
Line 413: Line 435:
   
 
<haskell>
 
<haskell>
  +
-- Updated Bot type
 
data Bot = Bot { botSocket :: Handle, startTime :: UTCTime }
 
data Bot = Bot { botSocket :: Handle, startTime :: UTCTime }
 
</haskell>
 
</haskell>
Line 419: Line 442:
   
 
<haskell>
 
<haskell>
  +
-- Connect to the server and return the initial bot state
 
connect :: IO Bot
 
connect :: IO Bot
 
connect = notify $ do
 
connect = notify $ do
Line 430: Line 454:
 
<haskell>
 
<haskell>
 
eval "!uptime" = uptime >>= privmsg
 
eval "!uptime" = uptime >>= privmsg
  +
eval ...
 
</haskell>
 
</haskell>
   
Line 435: Line 460:
   
 
<haskell>
 
<haskell>
  +
-- Get the current uptime
 
uptime :: Net String
 
uptime :: Net String
 
uptime = do
 
uptime = do
Line 488: Line 514:
 
* Port some commands from [[Lambdabot]].
 
* Port some commands from [[Lambdabot]].
   
Author: [http://www.cse.unsw.edu.au/~dons Don Stewart]
+
Author: Don Stewart
   
 
[[Category:Tutorials]]
 
[[Category:Tutorials]]

Latest revision as of 11:53, 1 August 2019

This tutorial is designed as a practical guide to writing real world code in Haskell and hopes to intuitively motivate and introduce some of the advanced features of Haskell to the novice programmer. Our goal is to write a concise, robust and elegant IRC bot in Haskell.

A packaged-up version of the code is available on GitHub.

Getting started

You'll need a reasonably recent version of GHC. Our first step is to get on the network. So let's start by importing modules from the standard library and the network package, and defining a server to connect to.

-- File 1.hs

import System.IO                      -- base
import qualified Network.Socket as N  -- network

-- Configuration options
myServer = "irc.freenode.org" :: String
myPort   = 6667 :: N.PortNumber

-- Toplevel program
main :: IO ()
main = do
    h <- connectTo myServer myPort
    t <- hGetContents h
    hSetBuffering stdout NoBuffering
    print t

-- Connect to a server given its name and port number
connectTo :: N.HostName -> N.PortNumber -> IO Handle
connectTo host port = do
    addr : _ <- N.getAddrInfo Nothing (Just host) (Just (show port))
    sock <- N.socket (N.addrFamily addr) (N.addrSocketType addr) (N.addrProtocol addr)
    N.connect sock (N.addrAddress addr)
    N.socketToHandle sock ReadWriteMode

The key here is the main function. This is the entry point to a Haskell program. We first connect to the server and get a socket h (wrapped as a Handle). We can then read and print any data we receive. We disable buffering (hSetBuffering) on standard output, as print renders strings on a single line, with newline characters escaped.

Put this code in the module 1.hs and we can then run it. Use whichever system you like:

Using runhaskell:

   $ runhaskell 1.hs
   "NOTICE AUTH :*** Looking up your hostname...\r\nNOTICE AUTH :***
   Checking ident\r\nNOTICE AUTH :*** Found your hostname\r\n ...

Or we can just compile it to an executable with GHC:

   $ ghc --make 1.hs -o tutbot
   Chasing modules from: 1.hs
   Compiling Main             ( 1.hs, 1.o )
   Linking ...
   $ ./tutbot
   "NOTICE AUTH :*** Looking up your hostname...\r\nNOTICE AUTH :***
   Checking ident\r\nNOTICE AUTH :*** Found your hostname\r\n ...

Or using GHCi:

   $ ghci 1.hs
   *Main> main
   "NOTICE AUTH :*** Looking up your hostname...\r\nNOTICE AUTH :***
   Checking ident\r\nNOTICE AUTH :*** Found your hostname\r\n ...

Great! We're on the network.

Talking IRC

Now we're listening to the server, we better start sending some information back. Three details are important: the nick, the user name, and a channel to join. So let's send those.

-- File 2.hs

import System.IO                      -- base
import qualified Network.Socket as N  -- network

-- Configuration options
myServer = "irc.freenode.org" :: String
myPort   = 6667 :: N.PortNumber
myChan   = "#tutbot-testing" :: String
myNick   = "tutbot" :: String

-- Toplevel program
main :: IO ()
main = do
    h <- connectTo myServer myPort
    write h "NICK" myNick
    write h "USER" (myNick ++ " 0 * :tutorial bot")
    write h "JOIN" myChan
    listen h

-- Connect to a server given its name and port number
connectTo :: N.HostName -> N.PortNumber -> IO Handle
connectTo host port = do
    addr : _ <- N.getAddrInfo Nothing (Just host) (Just (show port))
    sock <- N.socket (N.addrFamily addr) (N.addrSocketType addr) (N.addrProtocol addr)
    N.connect sock (N.addrAddress addr)
    N.socketToHandle sock ReadWriteMode

-- Send a message to a handle
write :: Handle -> String -> String -> IO ()
write h cmd args = do
    let msg = cmd ++ " " ++ args ++ "\r\n"
    hPutStr h msg          -- Send message on the wire
    putStr ("> " ++ msg)   -- Show sent message on the command line

-- Process each line from the server
listen :: Handle -> IO ()
listen h = forever $ do
    line <- hGetLine h
    putStrLn line
  where
    forever :: IO () -> IO ()
    forever a = do a; forever a

Now, we've done quite a few things here. Firstly, we set up a channel name and bot nickname. The main function has been extended to send messages back to the IRC server using a write function. Let's look at that a bit more closely:

-- Send a message to a handle
write :: Handle -> String -> String -> IO ()
write h cmd args = do
    let msg = cmd ++ " " ++ args ++ "\r\n"
    hPutStr h msg          -- Send message on the wire
    putStr ("> " ++ msg)   -- Show sent message on the command line

The write function takes 3 arguments; a handle (our socket), and then two strings representing an IRC protocol action, and any arguments it takes. write then builds an IRC message by concatenating strings and write it over the wire to the server. For debugging purposes we also print to standard output the message we send.

Our second function, listen, is as follows:

-- Process each line from the server
listen :: Handle -> IO ()
listen h = forever $ do
    line <- hGetLine h
    putStrLn line
  where
    forever :: IO () -> IO ()
    forever a = do a; forever a

This function takes a Handle argument, and sits in an infinite loop reading lines of text from the network and printing them. We take advantage of two powerful features; lazy evaluation and higher order functions to roll our own loop control structure, forever, as a normal function! forever takes a chunk of code as an argument, evaluates it and recurses - an infinite loop function. It is very common to roll our own control structures in Haskell this way, using higher order functions. No need to add new syntax to the language, lisp-like macros or meta programming - you just write a normal function to implement whatever control flow you wish. We can also avoid do-notation, and directly write: forever a = a >> forever a. Note that forever can also be found in the standard library base, in the module Control.Monad (with a more general type).

Let's run this thing:

$ runhaskell 2.hs
> NICK tutbot
> USER tutbot 0 * :tutorial bot
> JOIN #tutbot-testing
NOTICE AUTH :*** Looking up your hostname...
NOTICE AUTH :*** Found your hostname, welcome back
NOTICE AUTH :*** Checking ident
NOTICE AUTH :*** No identd (auth) response
:orwell.freenode.net 001 tutbot :Welcome to the freenode IRC Network tutbot
:orwell.freenode.net 002 tutbot :Your host is orwell.freenode.net
...
:tutbot!n=tutbot@aa.bb.cc.dd JOIN :#tutbot-testing
:orwell.freenode.net MODE #tutbot-testing +ns
:orwell.freenode.net 353 tutbot @ #tutbot-testing :@tutbot
:orwell.freenode.net 366 tutbot #tutbot-testing :End of /NAMES list.

And we're in business! From an IRC client, we can watch the bot connect:

   15:02 -- tutbot [n=tutbot@aa.bb.cc.dd] has joined #tutbot-testing
   15:02  dons> hello

And the bot logs to standard output:

   :dons!i=dons@my.net PRIVMSG #tutbot-testing :hello

We can now implement some commands.

A simple interpreter

Add these additional imports before changing the listen function.

import Data.List
import System.Exit
-- Connect to a server given its name and port number
listen :: Handle -> IO ()
listen h = forever $ do
    line <- hGetLine h
    putStrLn line
    let s = init line
    if isPing s then pong s else eval h (clean s)
  where
    forever :: IO () -> IO ()
    forever a = do a; forever a

    clean :: String -> String
    clean = drop 1 . dropWhile (/= ':') . drop 1

    isPing :: String -> Bool
    isPing x = "PING :" `isPrefixOf` x

    pong :: String -> IO ()
    pong x = write h "PONG" (':' : drop 6 x)

We add 3 features to the bot here by modifying listen. Firstly, it responds to PING messages: if ping s then pong s ... . This is useful for servers that require pings to keep clients connected. Before we can process a command, remember the IRC protocol generates input lines of the form:

:dons!i=dons@my.net PRIVMSG #tutbot-testing :!id foo

so we need a clean function to simply drop the leading ':' character, and then everything up to the next ':', leaving just the actual command content. We then pass this cleaned up string to eval, which dispatches bot commands.

-- Dispatch a command
eval :: Handle -> String -> IO ()
eval h "!quit"                   = write h "QUIT" ":Exiting" >> exitSuccess
eval h x | "!id " `isPrefixOf` x = privmsg h (drop 4 x)
eval _   _                       = return () -- ignore everything else

So, if the single string "!quit" is received, we inform the server and exit the program. If a string beginning with "!id " appears, we echo any argument string back to the server (the command is named after the identity function id, which just returns its argument). Finally, if no other matches occur, we do nothing.

We add the privmsg function - a useful wrapper over write for sending PRIVMSG lines to the server.

-- Send a privmsg to the channel
privmsg :: Handle -> String -> IO ()
privmsg h s = write h "PRIVMSG" (chan ++ " :" ++ s)

Here's a transcript from our minimal bot running in channel:

   15:12 -- tutbot [n=tutbot@aa.bb.cc.dd] has joined #tutbot-testing
   15:13  dons> !id hello, world!
   15:13  tutbot> hello, world!
   15:13  dons> !id very pleased to meet you.
   15:13  tutbot> very pleased to meet you.
   15:13  dons> !quit
   15:13 -- tutbot [n=tutbot@aa.bb.cc.dd] has quit [Client Quit]

Now, before we go further, let's refactor the code a bit.

Roll your own monad

A small annoyance so far has been that we've had to thread around our socket to every function that needs to talk to the network. The socket is essentially immutable state, that could be treated as a global read only value in other languages. In Haskell, we can implement such a structure using a reader monad. Monads are a very powerful abstraction, and we'll only touch on them here. The interested reader is referred to All About Monads. We'll be using a custom monad specifically to implement a read-only global state for our bot.

The key requirement is that we wish to be able to perform IO actions, as well as thread a small state value transparently through the program. As this is Haskell, we can take the extra step of partitioning our stateful code from all other program code, using a new type.

So let's define a small reader monad:

-- The 'Net' monad, a wrapper over IO, carrying the bot's immutable state.
data Bot = Bot { botSocket :: Handle }
type Net = ReaderT Bot IO

Firstly, we define a data type for the global state. In this case, it is the Bot type, a simple struct storing our network socket. We then layer this data type over our existing IO code, with a monad transformer. This isn't as scary as it sounds and the effect is that we can treat the socket as a global read-only value anywhere we need it. We'll call this new IO + state structure the Net monad. ReaderT is a type constructor, essentially a type function, that takes 2 types as arguments, building a result type: the Net monad type.

We can now throw out all that socket threading and grab the socket when we need it. The key steps are connecting to the server, followed by the initialisation of our new reader monad and then to run the main bot loop with that global value. We add a small function, which takes the intial bot state and evaluates the bot's run loop "in" the Net monad, using the Reader monad's runReaderT function:

loop st = runReaderT run st

where run is a small function to register the bot's nick, join a channel, and start listening for commands.

While we're here, we can tidy up the main function a little by using Control.Exception.bracket to explicitly delimit the connection, shutdown and main loop phases of the program - a useful technique.

-- Toplevel program
main :: IO ()
main = bracket connect disconnect loop
  where
    disconnect = hClose . socket
    loop st    = runReaderT run st

That is, the higher order function bracket takes 3 arguments: a function to connect to the server, a function to disconnect and a main loop to run in between. We can use bracket whenever we wish to run some code before and after a particular action - like forever, this is another control structure implemented as a normal Haskell function.

Rather than threading the socket around, we can now simply ask for it when needed. Note that the type of write changes - it is in the Net monad, which tells us that the bot must already by connected to a server (and thus it is ok to use the socket, as it is initialised).

-- Send a message out to the server we're currently connected to
write :: String -> String -> Net ()
write cmd args = do
    h <- asks botSocket
    let msg = cmd ++ " " ++ args ++ "\r\n"
    liftIO $ hPutStr h msg          -- Send message on the wire
    liftIO $ putStr ("> " ++ msg)   -- Show sent message on the command line

In order to use both state and IO, we use the liftIO function to lift an IO expression into the Net monad making that IO function available to code in the Net monad.

-- Imported from Control.Monad.IO.Class
liftIO :: IO a -> Net a

The monadic, stateful, exception-handling bot in all its glory:

-- File 4.hs

import Control.Exception              -- base
import Control.Monad.IO.Class         --
import Data.List                      --
import System.Exit                    --
import System.IO                      --
import qualified Network.Socket as N  -- network
import Control.Monad.Trans.Reader     -- transformers

-- Configuration options
myServer = "irc.freenode.org" :: String
myPort   = 6667 :: N.PortNumber
myChan   = "#tutbot-testing" :: String
myNick   = "tutbot" :: String

-- Set up actions to run on start and end, and run the main loop
main :: IO ()
main = bracket connect disconnect loop
  where
    disconnect = hClose . botSocket
    loop st = runReaderT run st

-- The 'Net' monad, a wrapper over IO, carrying the bot's immutable state.
data Bot = Bot { botSocket :: Handle }
type Net = ReaderT Bot IO

-- Connect to the server and return the initial bot state
connect :: IO Bot
connect = notify $ do
    h <- connectTo myServer myPort
    return (Bot h)
  where
    notify a = bracket_
      (putStrLn ("Connecting to " ++ myServer ++ " ...") >> hFlush stdout)
      (putStrLn "done.")
      a

-- Connect to the server and return a Handle (helper for connect)
connectTo :: N.HostName -> N.PortNumber -> IO Handle
connectTo host port = do
    addr : _ <- N.getAddrInfo Nothing (Just host) (Just (show port))
    sock <- N.socket (N.addrFamily addr) (N.addrSocketType addr) (N.addrProtocol addr)
    N.connect sock (N.addrAddress addr)
    N.socketToHandle sock ReadWriteMode

-- We're in the Net monad now, so we've connected successfully
-- Join a channel, and start processing commands
run :: Net ()
run = do
    write "NICK" myNick
    write "USER" (myNick ++ " 0 * :tutorial bot")
    write "JOIN" myChan
    listen

-- Send a message to the server we're currently connected to
write :: String -> String -> Net ()
write cmd args = do
    h <- asks botSocket
    let msg = cmd ++ " " ++ args ++ "\r\n"
    liftIO $ hPutStr h msg          -- Send message on the wire
    liftIO $ putStr ("> " ++ msg)   -- Show sent message on the command line

-- Process each line from the server
listen :: Net ()
listen = forever $ do
    h <- asks botSocket
    line <- liftIO $ hGetLine h
    liftIO (putStrLn line)
    let s = init line
    if isPing s then pong s else eval (clean s)
  where
    forever :: Net () -> Net ()
    forever a = do a; forever a

    clean :: String -> String
    clean = drop 1 . dropWhile (/= ':') . drop 1

    isPing :: String -> Bool
    isPing x = "PING :" `isPrefixOf` x

    pong :: String -> Net ()
    pong x = write "PONG" (':' : drop 6 x)

-- Dispatch a command
eval :: String -> Net ()
eval "!quit" = write "QUIT" ":Exiting" >> liftIO exitSuccess
eval x | "!id " `isPrefixOf` x = privmsg (drop 4 x)
eval _ = return ()  -- ignore everything else

-- Send a privmsg to the current chan + server
privmsg :: String -> Net ()
privmsg msg = write "PRIVMSG" (myChan ++ " :" ++ msg)

Note that we threw in a new control structure, notify, for fun. Now we're almost done! Let's run this bot. Using runhaskell:

   $ runhaskell 4.hs

or using GHC:

   $ ghc --make 4.hs -o tutbot
   Chasing modules from: 4.hs
   Compiling Main             ( 4.hs, 4.o )
   Linking ...
   $ ./tutbot

And from an IRC client we can watch it connect:

   15:26 -- tutbot [n=tutbot@aa.bb.cc.dd] has joined #tutbot-testing
   15:28  dons> !id all good?
   15:28  tutbot> all good?
   15:28  dons> !quit
   15:28 -- tutbot [n=tutbot@aa.bb.cc.dd] has quit [Client Quit]

So we now have a bot with explicit read-only monadic state, error handling, and some basic IRC operations. If we wished to add read-write state, we need only change the ReaderT transformer to StateT.

Extending the bot

Let's implement a basic new command: uptime tracking. Conceptually, we need to remember the time the bot starts. Then, if a user requests, we work out the total running time and print it as a string. A nice way to do this is to extend the bot's state with a start time field:

import Data.Time
-- Updated Bot type
data Bot = Bot { botSocket :: Handle, startTime :: UTCTime }

We can then modify the initial connect function to also set the start time.

-- Connect to the server and return the initial bot state
connect :: IO Bot
connect = notify $ do
    t <- getCurrentTime
    h <- connectTo myServer myPort
    return (Bot h t)

We then add a new case to the eval function, to handle uptime requests:

eval "!uptime" = uptime >>= privmsg
eval ...

This will run the uptime function and send it back to the server. uptime itself is:

-- Get the current uptime
uptime :: Net String
uptime = do
  now <- liftIO getCurrentTime
  zero <- asks startTime
  return (pretty (diffUTCTime now zero))

That is, in the Net monad, find the current time and the start time, and then calculate the difference, returning that number as a string. Rather than use the normal representation for dates, we'll write our own custom formatter for dates:

-- Pretty print the date in '1d 9h 9m 17s' format
pretty :: NominalDiffTime -> String
pretty diff =
    unwords
      . map (\(t, unit) -> show t ++ unit)
      $ if null diffs then [(0, "s")] else diffs
  where
    diffs :: [(Integer, String)]
    diffs = filter ((/= 0) . fst)
      $ decompose [(86400, "d"), (3600, "h"), (60, "m"), (1, "s")] (floor diff)
    decompose [] _ = []
    decompose ((secs, unit) : metrics) t =
      let (n, t') = t `divMod` secs
      in (n, unit) : decompose metrics t'

And that's it. Running the bot with this new command:

   16:03 -- tutbot [n=tutbot@aa.bb.cc.dd] has joined #tutbot-testing
   16:03  dons> !uptime
   16:03  tutbot> 51s
   16:03  dons> !uptime
   16:03  tutbot> 1m 1s
   16:12  dons> !uptime
   16:12  tutbot> 9m 46s

Where to now?

This is just a flavour of application programming in Haskell, and only hints at the power of Haskell's lazy evaluation, static typing, monadic effects and higher order functions. There is much, much more to be said on these topics. Some places to start:

Or take the bot home and hack! Some suggestions:

  • Use forkIO to add a command line interface, and you've got yourself an irc client with 4 more lines of code.
  • Port some commands from Lambdabot.

Author: Don Stewart