View source for Template Haskell

'''[http://www.haskell.org/th/ Template Haskell]''' is a [[GHC]] extension to Haskell that adds compile-time metaprogramming facilities.  The original design can be found here: http://research.microsoft.com/~simonpj/papers/meta-haskell/ .  It is [http://haskell.cs.yale.edu/ghc/docs/6.2/html/users_guide/template-haskell.html included] in GHC version 6.  

This page hopes to be a more central and organized repository of TH related things.

=What is Template Haskell?=
Template Haskell is an extension to Haskell 98 that allows you to do type-safe compile-time meta-programming, with Haskell both as the manipulating language and the language being manipulated. 

Intuitively Template Haskell provides new language features that allow us to convert back and forth between concrete syntax, i.e. what you would type when you write normal Haskell code, and abstract syntax trees. These abstract syntax trees are represented using Haskell datatypes and, at compile time, they can be manipulated by Haskell code. This allows you to reify (convert from concrete syntax to an abstract syntax tree) some code, transform it and splice it back in (convert back again), or even to produce completely new code and splice that in, while the compiler is compiling your module. 

For email about Template Haskell, use the [http://haskell.org/mailman/listinfo/glasgow-haskell-users GHC users mailing list].  It's worth joining if you start to use TH.

= Template Haskell specification =

Template Haskell is only documented rather informally at the moment.  Here are the main resources:

* [http://www.haskell.org/ghc/docs/latest/html/users_guide/template-haskell.html The user manual section on Template Haskell]
* [http://www.haskell.org/ghc/docs/latest/html/users_guide/template-haskell.html#th-quasiquotation The user manual section on quasi-quotation], which is closely related to Template Haskell.
* [http://research.microsoft.com/~simonpj/papers/meta-haskell/ The original Template Haskell paper]
* [http://research.microsoft.com/~simonpj/tmp/notes2.ps Notes on Template Haskell version 2], which describes changes since the original paper.  Section 8 describes the difficulty with pattern splices, which are therefore not implemented.
* [http://haskell.org/ghc/docs/7.0-latest/html/libraries/template-haskell-2.5.0.0/Language-Haskell-TH.html The Template Haskell API]

= Template Haskell tutorials and papers =

* Bulat's tutorials:
** http://www.haskell.org/bz/thdoc.htm
** http://www.haskell.org/bz/th3.htm
: One reader said "These docs are *brilliant* ! Exactly what I need to get an understanding of TH."

* Mark Snyder's Template Haskell chapter on the Software Generation and Configuration Report
** http://nix.cs.uu.nl/dist/courses/sgc-report-unstable-latest/manual/chunk-chapter/templatehaskell.html

* A very short tutorial to understand the basics in 10 Minutes.
** http://www.hyperedsoftware.com/blog/entries/first-stab-th.html

* GHC Template Haskell documentation
** http://www.haskell.org/ghc/docs/7.0.2/html/users_guide/template-haskell.html

* Papers about Template Haskell

** Template metaprogramming for Haskell, by Tim Sheard and Simon Peyton Jones, Oct 2002. [http://haskell.org/wikiupload/c/ca/Meta-haskell.ps [ps]] 
** Template Haskell: A Report From The Field, by Ian Lynagh, May 2003. [http://haskell.org/wikiupload/2/24/Template_Haskell-A_Report_From_The_Field.ps [ps]]
** Unrolling and Simplifying Expressions with Template Haskell, by Ian Lynagh, December 2002. [http://haskell.org/wikiupload/e/ed/Template-Haskell-Utils.ps [ps]]
** Automatic skeletons in Template Haskell, by Kevin Hammond, Jost Berthold and Rita Loogen, June 2003.  [http://haskell.org/wikiupload/6/69/AutoSkelPPL03.pdf [pdf]]
** Optimising Embedded DSLs using Template Haskell, by Sean Seefried, Manuel Chakravarty, Gabriele Keller, March 2004. [http://haskell.org/wikiupload/b/b5/Seefried04th-pan.pdf [pdf]]
** Typing Template Haskell: Soft Types, by Ian Lynagh, August 2004. [http://haskell.org/wikiupload/7/72/Typing_Template_Haskell_Soft_Types.ps [ps]]

= Other useful resources =

* [http://www.haskell.org/th/ The old Template Haskell web page].  Would someone feel like moving this material into the HaskellWiki?
* Old and probably not too useful for most but maybe... http://www.cse.unsw.edu.au/~chak/haskell/ghc/comm/exts/th.html
*[http://web.comlab.ox.ac.uk/oucl/work/ian.lynagh/Fraskell/ Fraskell documentation] & explanation of how Template Haskell is used to vastly speed it up.
*[[Quasiquotation]]
Feel free to update our Wikipedia entry
http://en.wikipedia.org/wiki/Template_Haskell

= Projects =

What are you doing/planning to do/have done with Template Haskell?

* The [http://www.ict.kth.se/org/ict/ecs/sam/projects/forsyde/www ForSyDe methodology] is currently implemented as a Haskell-based DSL which makes extensive use of Template Haskell.

* I have written a primitive (untyped) binding to the Objective-C runtime system on Mac OS X. It needs just TH, no "stub files" are created, no seperate utilities are required. Initial snapshot is at http://www.kfunigraz.ac.at/imawww/thaller/wolfgang/HOC020103.tar.bz2 -- WolfgangThaller

* I am writing Template Greencard - a reimplementation of GreenCard using TH.  Many bits work out really nicely.  A few bits didn't work so nicely - once I get some time to think, I'll try to persuade the TH folk to make some changes to fix some of these.  -- AlastairReid

* I'm writing Hacanon - a framework for automatic generation of C++ bindings. Read "automated Template Greencard for C++" (-: Darcs repo: http://www.ScannedInAvian.org/repos/hacanon - You'll need gccxml (http://www.gccxml.org/) to compile the exmples. - 27 Dec Lemmih.

* Following other FFI tools developers, I see some future for Template HSFFIG, especially when it comes to autogenerate peek and poke methods for structures defined in C; may be useful for implementation of certain network protocols such as X11 where layout of messages is provided as C structure/union declaration. - 16 Dec 2005 DimitryGolubovsky

* I am using Template Haskell as a mechanism to get parsed, typechecked code into an Ajax based Haskell Equational Reasoning tool [[Haskell Equational Reasoning Assistant]], as well as simplify the specification of equational relationships between pieces of code. There was a quicktime movie of the tool being used on http://www.gill-warbington.com/home/andy/share/hera1.html - AndyGill 

* I am working on functional metaprogramming techniques to enhance programming reliability and productivity, by reusing much of the existing compiler technology. Template Haskell is especially interesting for me because it permits to check size information of structures by the compiler, provided this information is available at compile time. This approach is especially appropriate for hardware designs, where the structures are fixed before the circuit starts operating. See our metaprogramming web page at http://www.infosun.fmi.uni-passau.de/cl/metaprog/ -- ChristophHerrmann(http://www.cs.st-and.ac.uk/~ch)

* I am using Template Haskell to do type safe database access. I initially [http://www.nabble.com/Using-Template-Haskell-to-make-type-safe-database-access-td17027286.html proposed this on haskell-cafe]. I connect to the database at compile-time and let the database do SQL parsing and type inference. The result from parsing and type inference is used to build a type safe database query which can executed at run-time. [[MetaHDBC | You can find the project page here]] -- [mailto:mads_lindstroem@yahoo.dk Mads Lindstrøm]

= Utilities =

Helper functions, debugging functions, or more involved code e.g. a monadic fold algebra for TH.Syntax.

* http://www.haskell.org/pipermail/template-haskell/2003-September/000176.html

= Known Bugs =

Take a look at the [http://hackage.haskell.org/trac/ghc/query?status=new&status=assigned&status=reopened&component=Template+Haskell&order=priority open bugs against Template Haskell] on the GHC bug tracker.

= Wish list =

Things that Ian Lynagh (Igloo) mentioned in his paper ''Template Haskell: A Report From The Field'' in May 2003 (available [http://www.haskell.org/th/papers.html here]), by section:

* Section 2 (curses)
** The ability to splice names (into "foreign import" declarations, in particular)
** The ability to add things to the export list from a splice(?)
** The ability to use things defined at the toplevel of a module from splices in that same module (would require multi-stage compilation, as opposed to the current approach of expanding splices during typechecking)

* Section 3 (deriving instances of classes)
** <strike>First-class reification</strike> (the <hask>reify</hask> function)
** A way to discover whether a data constructor was defined infix or prefix (which is necessary to derive instances for <hask>Read</hask> and <hask>Show</hask> as outlined in [http://www.haskell.org/onlinereport/derived.html The Haskell 98 Report: Specification of Derived Instances]) (if there is a way, [http://www-users.cs.york.ac.uk/~ndm/derive/ Derive] seems ignorant of it)
** Type/context splicing (in <hask>instance</hask> headers in particular)

* Section 4 (printf)
** He says something to the effect that a pattern-matching form of the quotation brackets would be cool if it was expressive enough to be useful, but that this would be hard. (Don't expect this anytime soon.)

* Section 5 (fraskell)
** Type information for quoted code (so that simplification can be done safely even with overloaded operations, like, oh, <hask>(+)</hask>)

* Section 6 (pan)
** Type info again, and strictnes info too (this one seems a bit pie-in-the-sky...)

(Please leave the implemented ones here, but crossed off.)

Any other features that may be nice, and TH projects you'd want to see.

* A TH tutorial (mainly a distillation and update of ''Template Meta-programming in Haskell'' at this point)
* <strike>Write Haddock documentation for the Template Haskell library (http://hackage.haskell.org/trac/ghc/ticket/1576).</strike>
* Make `reify` on a class return a list of the instances of that class (http://www.haskell.org/pipermail/template-haskell/2005-December/000503.html). (See also [http://hackage.haskell.org/trac/ghc/ticket/1577 GHC ticket #1577].)
* A set of simple examples on this wiki page
* A TH T-shirt with new logo to wear at conferences
* (Long-term) Unify Language.Haskell.Syntax with Language.Haskell.TH.Syntax so there's just one way to do things (http://hackage.haskell.org/package/haskell-src-meta does a one-way translation, for haskell-src-exts)

---------------

= Tips and Tricks =

== What to do when you can't splice that there ==

When you try to splice something into the middle of a template and find that you just can't, instead of getting frustrated about it, why not use the template to see what it would look like in longhand? 

First, an excerpt from a module of my own. I, by the way, am SamB.
<haskell>
{-# OPTIONS_GHC -fglasgow-exts -fth #-}

module MMixMemory where

import Data.Int
import Data.Word

class (Integral int, Integral word)
    => SignConversion int word | int -> word, word -> int where
                               
    toSigned   :: word -> int
    toSigned   = fromIntegral
    toUnsigned :: int -> word
    toUnsigned = fromIntegral

</haskell>

Say I want to find out what I need to do to splice in the types for an instance declaration for the SignConversion class, so that I can declare instances for Int8 with Word8 through Int64 with Word64. So, I start up good-ol' GHCi and do the following:

<haskell>
$ ghci -fth -fglasgow-exts
Prelude> :l MMixMemory
*MMixMemory> :m +Language.Haskell.TH.Syntax
*MMixMemory Language.Haskell.TH.Syntax> runQ [d| instance SignConversion Int Word where |] >>= print
[InstanceD [] (AppT (AppT (ConT MMixMemory.SignConversion) (ConT GHC.Base.Int)) (ConT GHC.Word.Word)) []]
</haskell>

== Why does <tt>runQ</tt> crash if I try to reify something? ==

This program will fail with an error message when you run it:
<haskell>
  main = do info <- runQ (reify (mkName "Bool")) -- more hygenic is: (reify ''Bool)
            putStrLn (pprint info)
</haskell>
Reason: <tt>reify</tt> consults the type environment, and that is not available at run-time.  The type of <tt>reify</tt> is 
<haskell>
  reify :: Quasi m => Q a -> m a
</haskell>
The IO monad is a poor-man's instance of <tt>Quasi</tt>; it can allocate unique names and gather error messages, but it can't do <tt>reify</tt>.  This error should really be caught statically.

Instead, you can run the splice directly (ex. in ghci -XTemplateHaskell), as the following shows:

<haskell>
GHCi> let tup = $(tupE $ take 4 $ cycle [ [| "hi" |] , [| 5 |] ])
GHCi> :type tup
tup :: ([Char], Integer, [Char], Integer)

GHCi> tup
("hi",5,"hi",5)

GHCi> $(stringE . show =<< reify ''Int)
"TyConI (DataD [] GHC.Types.Int [] [NormalC GHC.Types.I# [(NotStrict,ConT GHC.Prim.Int#)]] [])"
</haskell>

Here's an [http://www.haskell.org/pipermail/glasgow-haskell-users/2006-August/010844.html email thread with more details].

-----------------
= Examples =
== Tuples ==
=== Select from a tuple ===

An example to select an element from a tuple of arbitrary size.  Taken from [http://www.haskell.org/th/papers/meta-haskell.ps this paper].

Use like so:

  > $(sel 2 3) ('a','b','c')
  'b'
  > $(sel 3 4) ('a','b','c','d')
  'c'


<haskell>
sel :: Int -> Int -> ExpQ
sel i n = [| \x -> $(caseE [| x |] [alt]) |]
    where alt :: MatchQ
          alt = match pat (normalB rhs) []

          pat :: Pat
          pat = tupP (map varP as)

          rhs :: ExpQ
          rhs = varE(as !! (i -1)) -- !! is 0 based

          as :: [String]
          as = ["a" ++ show i | i <- [1..n] ]
</haskell>

Alternately:

<haskell>
sel' i n = lamE [pat] rhs
    where pat = tupP (map varP as)
          rhs = varE (as !! (i - 1))
          as  = [ "a" ++ show j | j <- [1..n] ]
</haskell>

=== Apply a function to the n'th element ===

<haskell>
tmap i n = do
    f <- newName "f"
    as <- replicateM n (newName "a")
    lamE [varP f, tupP (map varP as)] $
        tupE [  if i == i'
                    then [| $(varE f) $a |]
                    else a
               | (a,i') <- map varE as `zip` [1..] ]
</haskell>

Then tmap can be called as:

  > $(tmap 3 4) (+ 1) (1,2,3,4)
  (1,2,4,4)

=== Convert the first n elements of a list to a tuple ===

This example creates a tuple by extracting elemnts from a list.  Taken from
[http://www.xoltar.org/2003/aug/13/templateHaskellTupleSample.html www.xoltar.org]

Use like so:

  > $(tuple 3) [1,2,3,4,5]
  (1,2,3)
  > $(tuple 2) [1,2]
  (1,2)

<haskell>
tuple :: Int -> ExpQ
tuple n = [|\list -> $(tupE (exprs [|list|])) |]
  where
    exprs list = [infixE (Just (list))
                         (varE "!!")
                         (Just (litE $ integerL (toInteger num)))
                    | num <- [0..(n - 1)]]
</haskell>

An alternative that has more informative errors (a failing pattern match failures give an exact location):

<haskell>
tuple :: Int -> ExpQ
tuple n = do
    ns <- replicateM n (newName "x")
    lamE [foldr (\x y -> conP '(:) [varP x,y]) wildP ns] (tupE $ map varE ns)
</haskell>

=== Un-nest tuples ===
Convert nested tuples like (a,(b,(c,()))) into (a,b,c) given the length to generate.

<haskell>
unNest n = do
    vs <- replicateM n (newName "x")
    lamE [foldr (\a b -> tupP [varP a , b])
                (conP '() [])
                vs]
         (tupE (map varE vs))
</haskell>



== [[Template Haskell/Marshall Data|Marshall a datatype to and from Dynamic]] ==
This approach is an example of using template haskell to delay typechecking
to be able to abstract out the repeated calls to fromDynamic:

<haskell>
data T = T Int String Double

toT :: [Dynamic] -> Maybe T
toT [a,b,c] = do
    a' <- fromDynamic a
    b' <- fromDynamic b
    c' <- fromDynamic c
    return (T a' b' c')
toT _ = Nothing
</haskell>

== Printf ==
This example taken from: http://haskell.cs.yale.edu/ghc/docs/6.0/html/users_guide/template-haskell.html

Build it using a command similar to one of the following (depending on your environment):

  ghc/compiler/stage3/ghc-inplace --make -fglasgow-exts -package haskell-src main.hs -o main.exe
  ghc --make -fth Main.hs -o printfTest

Main.hs:

<haskell>
module Main where

-- Import our template "pr"
import Printf ( pr )

-- The splice operator $ takes the Haskell source code
-- generated at compile time by "pr" and splices it into
-- the argument of "putStrLn".
main = putStrLn ( $(pr "Hello") )
</haskell>

Printf.hs:

<haskell>
module Printf where

-- Skeletal printf from the paper.
-- It needs to be in a separate module to the one where
-- you intend to use it.

-- Import some Template Haskell syntax
import Language.Haskell.TH.Syntax

-- Describe a format string
data Format = D | S | L String

-- Parse a format string.  This is left largely to you
-- as we are here interested in building our first ever
-- Template Haskell program and not in building printf.
parse :: String -> [Format]
parse s   = [ L s ]

-- Generate Haskell source code from a parsed representation
-- of the format string.  This code will be spliced into
-- the module which calls "pr", at compile time.
gen :: [Format] -> ExpQ
gen [D]   = [| \n -> show n |]
gen [S]   = [| \s -> s |]
gen [L s] = stringE s

-- Here we generate the Haskell code for the splice
-- from an input format string.
pr :: String -> ExpQ
pr s      = gen (parse s)
</haskell>

== Handling Options with Templates ==
A common idiom for treating a set of options, e.g. from GetOpt, is to define a datatype with all the flags and using a list over this datatype:

<haskell>
data Options = B1 | B2 | V Integer

options = [B1, V 3]
</haskell>

While it's simple testing if a Boolean flag is set (simply use "elem"), it's harder to check if an option with an argument is set. It's even more tedious writing helper-functions to obtain the value  from such an option since you have to explicitely "un-V" each. Here, Template Haskell can be (ab)used to reduce this a bit. The following example provides the module "OptionsTH" which can be reused regardless of the constructors in "Options". Let's start with showing how we'd like to be able to program. Notice that the resulting lists need some more treatment e.g. through "foldl".

Options.hs:

<haskell>
module Main where

import OptionsTH
import Language.Haskell.TH.Syntax

data Options = B1 | B2 | V Int | S String deriving (Eq, Read, Show)

options = [B1, V 3]

main = do
  print foo -- test if B1 set:               [True,False]
  print bar -- test if V present, w/o value: [False,True]
  print baz -- get value of V if available:  [Nothing,Just 3]

foo :: [Bool]
-- Query constructor B1 which takes no arguments
foo = map $(getopt (THNoArg (mkArg "B1" 0))) options

bar :: [Bool]
-- V is a unary constructor. Let mkArg generate the required
-- wildcard-pattern "V _".
bar = map $(getopt (THNoArg (mkArg "V" 1))) options

-- Can't use a wildcard here!
baz :: [(Maybe Int)]
baz = map $(getopt (THArg (conP "V" [varP "x"]))) options
</haskell>

OptionsTH.hs

<haskell>
module OptionsTH where

import Language.Haskell.TH.Syntax

-- datatype for querying options:
-- NoArg: Not interested in value (also applies to Boolean flags)
-- Arg:   Grep value of unary(!) constructor
data Args = THNoArg Pat | THArg Pat

getopt :: Args -> ExpQ
getopt (THNoArg pat) = lamE [varP "y"] (caseE (varE "y") [cons0, cons1])
 where
  cons0 = match pat   (normalB [| True  |]) []
  cons1 = match wildP (normalB [| False |]) []

-- bind "var" for later use!
getopt (THArg pat@(ConP _ [VarP var])) = lamE [varP "y"] (caseE (varE "y") [cons0, cons1])
 where
  cons0 = match pat   (normalB (appE [|Just|] (varE var))) []
  cons1 = match wildP (normalB [|Nothing|]) []

mkArg :: String -> Int -> Pat
mkArg k c = conP k (replicate c wildP)
</haskell>

While the example might look contrived for the Boolean options which could have been tested much easier, it shows how both types of arguments can be treated in a similar way.

=== Limitations ===
<tt>getopt (THArg pat)</tt> is only able to treat unary constructors. See the pattern-binding: It matches exactly a single VarP.

=== Improvements ===
The following reduces things even a bit more, though I still don't know if I like it. It only works since <tt>c</tt> is either 0 or 1.

<haskell>
mkArg k c = conP k (replicate c (varP "x"))

baz = map $(getopt (THArg (mkArg "V" 1)))
</haskell>
-- VolkerStolz

== Generic constructor for records ==

I have a large number of record types like this, of different length:

<haskell>
data PGD = PGD {
    pgdXUnitBase           :: !Word8,
    pgdYUnitBase           :: !Word8,
    pgdXLUnitsperUnitBase  :: !Word16
}
</haskell>

Currently I use GHC's Binary module to read them from files; it can handle
types like <tt>(Word8, (Word8, Word16))</tt>, but there was no easy way to generate
the correct amount of "uncurry" calls for automatically grabbing each element.

With Template Haskell, the instance declarations are now written as such:

<haskell>
instance Binary PGD where
    get bh = do a <- get bh ; return $ $(constrRecord PGD) a
</haskell>

Here the trick lies in constrRecord, which is defined as:

<haskell>
constrRecord x = reify exp where
    reify   = \(Just r) -> appE r $ conE $ last args
    exp     = foldl (dot) uncur $ replicate terms uncur
    terms   = ((length args) `div` 2) - 2
    dot x y = (Just $ infixE x (varE ".") y)
    uncur   = (Just [|uncurry|])
    args    = words . show $ typeOf x
</haskell>

-- AutrijusTang

== 'generic' zipWith ==
A generalization of zipWith to almost any data. Demonstrates the ability to do dynamic binding with TH splices (note 'dyn').

<haskell>
zipCons :: Name -> Int -> [String] -> ExpQ
zipCons tyName ways functions = do
    let countFields :: Con -> (Name,Int)
        countFields x = case x of
            NormalC n (length -> fields) -> (n, fields)
            RecC n (length -> fields) -> (n,fields)
            InfixC _ n _ -> (n,2)
            ForallC _ _ ct -> countFields ct

    TyConI (DataD _ _ _ [countFields -> (c,n)] _) <- reify tyName
    when (n /= length functions) $ fail "wrong number of functions named"
    vs <- replicateM ways $ replicateM n $ newName "x"
    lamE (map (conP c . map varP) vs) $
        foldl (\con (vs,f) ->
                  con `appE`
                    foldl appE
                        (dyn f)
                        (map varE vs))
              (conE c)
              (transpose vs `zip` functions)
</haskell>

This example uses whichever '+' is in scope when the expression is spliced:

<haskell>
:type $(zipCons ''(,,,) 2 (replicate 4 "+"))

  $(zipCons ''(,,,) 2 (replicate 4 "+"))
    :: (Num t, Num t1, Num t2, Num t3) =>
        (t, t1, t2, t3) -> (t, t1, t2, t3) -> (t, t1, t2, t3)
</haskell>


==[[Template haskell/Instance deriving example|Instance deriving example]]==
An example using a 'deriving function' to generate a method instance 
per constructor of a type. The deriving function provides the body of the
method.

Note that this example assumes that the functions of the class take a parameter that is the same type as instance is parameterized with. 

The message [http://www.haskell.org/pipermail/template-haskell/2006-August/000581.html email message] contains the full source ([http://www.iist.unu.edu/~vs/haskell/TH_render.hs extracted file]).

== [[Quasiquotation|QuasiQuoters]] ==
New in ghc-6.10 is -XQuasiQuotes, which allows one to extend ghc's syntax from library code. Quite a few examples are given in [http://hackage.haskell.org/package/haskell-src-meta haskell-src-meta].

=== Similarity with splices ===

Quasiquoters used in expression contexts (those using the ''quoteExp'') behave to a first approximation like regular TH splices:

<haskell>
simpleQQ = QuasiQuoter { quoteExp = stringE } -- in another module

[$simpleQQ| a b c d |] == $(quoteExp simpleQQ " a b c d ")
</haskell>

[[Category:Language extensions]]