X window programming in Haskell

From HaskellWiki

[WARNING: This page is extremely outdated and likely obsolete.]

This tutorial will show you how to write a simple X application using the low level C library, Xlib. The goal is to write a simple text-based clock displaying the system time, running on top of every other application - like a status bar would.

While the application is fairly simple, it still requires us to know quite a few details about X and Xlib to write a proper X application.

Target audience[edit]

This tutorial is dedicated to the intermediate Haskell coder. While I will try to write the simplest code I can (probably it will even look the dumbest, but that's me), I'm not going into much details about the Haskell part.

Goals[edit]

What are we going to learn:

  • how to create a window and set, or change, its attributes;
  • how to draw in that window, specifically some text, with some properties, like fonts or colors;
  • how to properly update the window;
  • how to handle events, like a mouse button press.

Background reading[edit]

These are some links that can be used as reference:

Prerequisites[edit]

In order to compile the following code examples you need at least:

  • Version 1.4.2 or greater of X11, the Haskell binding to the X11 graphics library.

Hello world![edit]

Let's start with the usual simple "Hello World": 

module Main where
import Graphics.X11.Xlib
import System.Exit (exitWith, ExitCode(..))
import Control.Concurrent (threadDelay)

main :: IO ()
main =
    do dpy <- openDisplay ""
       let dflt = defaultScreen dpy
           border =  blackPixel dpy dflt
           background = whitePixel dpy dflt
       rootw  <- rootWindow dpy dflt
       win <- createSimpleWindow dpy rootw 0 0 100 100 1 border background
       setTextProperty dpy win "Hello World" wM_NAME 
       mapWindow dpy win
       sync dpy False
       threadDelay (10 * 1000000)
       exitWith ExitSuccess

The first function, openDisplay, is the interface to the Xlib function XOpenDisplay(), and opens a connection to the X server that controls a display. The connection is returned and bound to dpy. By applying defaultScreen, the interface to XDefaultScreen, we get the default screen, that is required in many of the following functions. With rootWindow, the interface to XRootWindow(), we get the root window. We need it in order to set the parent window in the most important function of the above code: createSimpleWindow, the interface to XCreateSimpleWindow.

This function takes as arguments: the display, the parent window of the window to be created, the x position, the y position, the width, the height, the border width, the border pixel, and the background pixel.

The x and y positions are relative to the upper left corner of the parent window's inside borders.

In order to retrieve the values of the black and white pixels for that specific screen, we use two specific functions: blackPixel, the interface to the X11 library function BlackPixel, and whitePixel, the interface to the X11 library function WhitePixel

The function createSimpleWindow will return the window ID and, with this ID, we can start manipulating our newly created window, as we do, in the above code, with the function setTextProperty, interface to the X11 library function XSetTextProperty().

This function is needed by our code to set the window's name so your window manager will display on some decoration attached to the window (other window managers will not display anything, for instance a tiling WM like Xmonad)

To set the window's name we need to manipulate the XTextProperty structure.

Properties, such as the XTextProperty, have a string name and a numerical identifier called an atom. An atom is an ID that uniquely identifies a particular property. Property name strings are typically all upper case - with the first letter in low case when translated into Haskell - with words separated by underscores. In our example, we set the WM_NAME property to "Hello World".

Creating and manipulating a window is just the first step to have a new window displayed. In order for the window to become visible we must map it with mapWindow, the interface to the X11 library function XMapWindow(). This will make the window visible.

Xlib will not send requests and calls to the X server immediately, but will buffer them and send the full buffer when some given conditions are met.

One way to force the flushing of the output buffer is to call sync, the interface to the X11 library function XSync(), which takes 2 arguments: the connection (dpy) and a Boolean value that indicates whether XSync() must discard all events on the event queue.

After that, the X server will eventually display our window.

The rest of the above example does nothing else but block execution for 10 seconds (to let you stare at your newly created window) and then exits.

Window attributes[edit]

Even though in our "Hello World" example we set the window's dimension, we have no assurance that the window manager will respect our decision.

Xmonad, for instance, will just create a window with the dimensions needed to fill its tiled screen, no matter what you set in createSimpleWindow.

But we decided to write a small clock that will behave as a statusbar, that is to say, we want to create a window that will specifically not be managed by the window manager.

In order to achieve this result we need to start dealing with window's attributes.

There are two ways of dealing with window's attributes: the first is to set them at window's creation time, but in that case createSimpleWindow is not powerful enough.

The second way is to change window's attributes after the window's has been created.

Setting window's attribute at creation time[edit]

In order to set window's attributes at creation time, the window must be created with createWindow, the interface to the X11 library function XCreateWindow().

The type signature of this function is quite long: 

createWindow :: Display -> Window 
                -> Position -> Position 
                -> Dimension -> Dimension 
                -> CInt 
                -> CInt 
                -> WindowClass 
                -> Visual 
                -> AttributeMask 
                -> Ptr SetWindowAttributes 
                -> IO Window

That is to say:

  • the connection and the parent window
  • the x and y position (origins in the upper left corner of the inside border of

the parent window)

  • width and height
  • border width
  • depth of screen
  • the window's class
  • the visual
  • the attribute mask
  • and the pointer to the

XSetWindowAttributes foreign C structure.

This last one gives you an idea of the type of operation we must do in order to create a window (createSimpleWindow is just a specialization of this more complicated createWindow, with some arguments filled in with defaults): we need a function to allocate some memory for the creation of the foreign C structure, and then manipulate this foreign structure from within this function.

The needed function is allocaSetWindowAttributes, whose type indeed is: 

allocaSetWindowAttributes :: (Ptr SetWindowAttributes -> IO a) -> IO a

allocaSetWindowAttributes will take a function which takes the pointer to the foreign structure as its argument. This function will perform an IO action that is the action returned by allocaSetWindowAttributes.

In our case allocaSetWindowAttributes will take a function that will use createWindow to return the new window.

So, we will need to use createWindow inside allocaSetWindowAttributes. We will soon see how. But first let's analyze the other arguments of createWindow.

The display, the parent window, the coordinates and dimensions are the same as with createSimpleWindow. But now we must specify the depth of the screen, the window's class, the visual and the attribute mask. We also need to manipulate the XSetWindowAttribute after its creation by allocaSetWindowAttributes, before calling createWindow.

The depth is the number of bits available for each pixel to represent colors while the visual is way pixel values are translated to produce colors on the monitor.

We are going to use defaultDepthOfScreen, interface to the X11 library function XDefaultDepthOfScreen(), in order to retrieve the default screen depth.

For the visual we are going to use defaultVisualOfScreen, interface to the X11 library function DefaultVisualOfScreen.

The WindowClass can either be copyFromParent, inputOutput, or inputOnly. In the first case the class is copied from the class of the parent window. An inputOnly window can only be used for receiving input events. In our code we are going to use inputOutput windows, windows that can receive input events and that can also be used to display some output.

The attributeMask "specifies which window attributes are defined in the attributes argument. This mask is the bitwise inclusive OR of the valid attribute mask bits. If value mask is zero, the attributes are ignored and are not referenced." (see http://www.tronche.com/gui/x/xlib/window/XCreateWindow.html).

In other words, in order to set more then one attribute, you need to pass a value mask such as: 

attrmask = cWOverrideRedirect .|. cWBorderPixel .|. cWBackPixel .|. etc ...

and set each of this attributes within allocaSetWindowAttributes with specific attribute setting functions.

Among these functions the one we need: set_override_redirect, whose type is: 

set_override_redirect :: Ptr SetWindowAttributes -> Bool -> IO ()

This function takes the pointer to the XSetWindowAttributes structure and the flag to be set (True or False).

For the list of available attributes see the AttributeMask type definition.

For their meaning see the XSetWindowAttributes structure reference.

Now, our goal was to create a window that the window manager is going to ignore, and in order to do that all we need to set the attribute CWOverrideRedirect to True. And now we know how to do it.

Okay, it's time to introduce our function to create new windows with the CWOverrideRedirect set to True 

mkUnmanagedWindow :: Display
                  -> Screen
                  -> Window
                  -> Position
                  -> Position
                  -> Dimension
                  -> Dimension
                  -> IO Window
mkUnmanagedWindow dpy scr rw x y w h = do
  let visual = defaultVisualOfScreen scr
      attrmask = cWOverrideRedirect
  win <- allocaSetWindowAttributes $ 
         \attributes -> do
           set_override_redirect attributes True
           createWindow dpy rw x y w h 0 (defaultDepthOfScreen scr) 
                        inputOutput visual attrmask attributes                                
  return win

Like simpleCreateWindow, our function is a wrapper around createWindow, but this time we are manually setting the CWOverrideRedirect flag.

As you see our function, unlike createSimpleWindow, does not have, among its arguments, the background and the border pixels. This colors can be set, for windows created with createWindow, using the attribute mask, and setting CWBackPixel and CWBorderPixel with the needed functions: set_background_pixel and set_border_pixel.

By the way, setting the border color with this version of mkUnmanagedWindow is actually useless since the border width is set to zero. In the next example we will set it to 1.

Our function needs also the screen now, since we have to retrieve the default depth and visual.

We can now rewrite our initial code using the new function now. 

module Main where
import Data.Bits
import Graphics.X11.Xlib
import System.Exit (exitWith, ExitCode(..))
import Control.Concurrent (threadDelay)

main :: IO ()
main =
    do dpy <- openDisplay ""
       let dflt = defaultScreen dpy
           scr = defaultScreenOfDisplay dpy
       rootw  <- rootWindow dpy dflt
       win <- mkUnmanagedWindow dpy scr rootw 0 0 100 100
       setTextProperty dpy win "Hello World" wM_NAME 
       mapWindow dpy win
       sync dpy False
       threadDelay (10 * 1000000)
       exitWith ExitSuccess

mkUnmanagedWindow :: Display
                  -> Screen
                  -> Window
                  -> Position
                  -> Position
                  -> Dimension
                  -> Dimension
                  -> IO Window
mkUnmanagedWindow dpy scr rw x y w h = do
  let visual = defaultVisualOfScreen scr
      attrmask = cWOverrideRedirect .|. cWBorderPixel .|. cWBackPixel
  win <- allocaSetWindowAttributes $ 
         \attributes -> do
           set_override_redirect attributes True
           set_background_pixel attributes $ whitePixel dpy (defaultScreen dpy)
           set_border_pixel attributes $ blackPixel dpy (defaultScreen dpy)
           createWindow dpy rw x y w h 1 (defaultDepthOfScreen scr)
                        inputOutput visual attrmask attributes                                
  return win

Okay, let's give it a try. Did you see? Now the window will be placed in the specified x and y position, with the given dimensions. No window manager decorations, and so, no name displayed.

Changing an existing window's attributes[edit]

This task requires XChangeWindowAttrbutes(), requiring X11-1.4.2 or newer.

In order to change a window's attributes we just need the window ID in that specific X server, after that we need to unmap the window first, and then change its attributes with changeWindowAttributes, the interface to XChangeWindowAttrbutes().

Here's the code: 

module Main where

import Graphics.X11.Xlib
import Graphics.X11.Xlib.Extras
import System.Environment

usage :: String -> String
usage n = "Usage: " ++ n ++ " manage/unmanage windowID"

main :: IO ()
main = do
  args <- getArgs
  pn <- getProgName
  let (win,ac) = case args of
                   [] -> error $ usage pn
                   w -> case (w !!0) of 
                          "manage" -> (window, False)
                          "unmanage" ->  (window, True)
                          _ -> error $ usage pn
                       where window = case  (w !! 1) of 
                                               [] -> error $ usage pn
                                               w -> read w :: Window
  dpy <- openDisplay ""
  unmapWindow dpy win
  sync dpy False
  allocaSetWindowAttributes $
       \attributes -> do
         set_override_redirect attributes ac
         changeWindowAttributes dpy win cWOverrideRedirect attributes
  mapWindow dpy win
  sync dpy False

Save it as Unmanage.hs and compile with: 

ghc --make Unmanage.hs -o unmanage

To use it you need to retrieve the window ID with the stand alone utility 

xwininfo

Then you run the above code with: 

unmanage unmanage/manage windowID

to set override_redirect to True or False.

Obviously the important part of the code is this: 

  dpy <- openDisplay ""
  unmapWindow dpy win
  sync dpy False
  allocaSetWindowAttributes $
       \attributes -> do
         set_override_redirect attributes ac
         changeWindowAttributes dpy win cWOverrideRedirect attributes
  mapWindow dpy win
  sync dpy False

where we:

  1. connect to the X server
  2. unmap the window
  3. flush the output buffer to have the X server actually unmap the window
  4. change the attributes with the same procedure we used to set them when creating

the window

  1. map the window again
  2. flush the output buffer to see the change take effect.

You can modify this program to change other window's attributes.

Colors and color Ddepth[edit]

So far we have set the window background color as a window attribute. This is not the most convenient way to set the window background color: if we need to change it, we must change the window's attribute, and we have seen that this task requires unmapping the window, flushing the output with changeWindowAttributes within changeWindowAttributes, remapping the window and reflushing the output buffer.

In the following sections we are going to adopt a more efficient way of setting the window's background color: we will start drawing into the window. But first we must familiarize with colors and the way the X server deals with them.

So far we have set the colors by using some functions to retrieve their pixel values: blackPixel and whitePixel. These functions take the display and the default screen and return respectively the pixel values for the black and the white colors in that screen.

A color is represented by a 32-bit unsigned integer, called a pixel value. The elements affecting the pixel representation of a color are:

  1. the color depth;
  2. the colormap, which is a table containing red, green, and blue intensity values;
  3. the visual type.

All these elements are specific to a given piece of hardware, and so our X application must detect them in order to set colors appropriately for that given hardware.

The approach we are going to use to accomplish this task is this: we are going to use named colors, or colors represented by RGB triple, such as "red", "yellow", or "#FFFFFF", etc; and we are going to translate these colors into the pixel values appropriate for the screen we are operating on.

In order to achieve our goal we are going to use the function allocNamedColor which is the interface to the X11 library function XAllocNamedColor().

The type signature of allocNamedColor is: 

allocNamedColor :: Display -> Colormap -> String -> IO (Color, Color)

That is to say, given a display connection, a color map and a string - our color representation -, this function will return a tuple with the closest RGB values provided by the hardware and the exact RGB values, both encoded in a Haskell Color data type. We will use the first approximated value.

The Color data type has a field name we will use to retrieve the needed pixel value: color_pixel.

We can now write this helper function: 

initColor :: Display -> String -> IO Pixel
initColor dpy color = do
  let colormap = defaultColormap dpy (defaultScreen dpy)
  (approx,real) <- allocNamedColor dpy colormap color
  return $ color_pixel approx

To retrieve the colormap of the screen we used defaultColormap, the interface to the X11 library function XDefaultColormap(), which requires the display and the screen, and returns the colormap of that screen.

We can now rewrite our example using this new approach: 

module Main where
import Data.Bits
import Graphics.X11.Xlib
import System.Exit (exitWith, ExitCode(..))
import Control.Concurrent (threadDelay)

main :: IO ()
main =
    do dpy <- openDisplay ""
       let dflt = defaultScreen dpy
           scr = defaultScreenOfDisplay dpy
       rootw  <- rootWindow dpy dflt
       win <- mkUnmanagedWindow dpy scr rootw 0 0 100 100
       setTextProperty dpy win "Hello World" wM_NAME 
       mapWindow dpy win
       sync dpy False
       threadDelay (10 * 1000000)
       exitWith ExitSuccess

mkUnmanagedWindow :: Display
                  -> Screen
                  -> Window
                  -> Position
                  -> Position
                  -> Dimension
                  -> Dimension
                  -> IO Window
mkUnmanagedWindow dpy scr rw x y w h = do
  let visual = defaultVisualOfScreen scr
      attrmask = cWOverrideRedirect .|. cWBorderPixel .|. cWBackPixel
  background_color <- initColor dpy "red"
  border_color <- initColor dpy "black" 
  win <- allocaSetWindowAttributes $ 
         \attributes -> do
           set_override_redirect attributes True
           set_background_pixel attributes background_color
           set_border_pixel attributes border_color
           createWindow dpy rw x y w h 1 (defaultDepthOfScreen scr)
                        inputOutput visual attrmask attributes                                
  return win


initColor :: Display -> String -> IO Pixel
initColor dpy color = do
  let colormap = defaultColormap dpy (defaultScreen dpy)
  (apros,real) <- allocNamedColor dpy colormap color
  return $ color_pixel apros

Just give it a try. Now you can also experiment with different colors. This approach will assure that our application will work no matter the color depth of the screen we are working on.

Drawing in windows[edit]

The X server provides two objects that can be used to draw something to: windows and pixmaps.

In this section we will start drawing into windows.

We have seen that changing the background color of a window is a troublesome operation, since the window must be unmapped and remapped, memory for a foreign structure allocated, and so on.

Instead, we can use some graphic operations to draw a rectangle over the window. We will latter manipulate the foreground, visible, color of this rectangle, that will become the new background of our window.

We can also use multiple rectangles with different dimension to decorate our window with a border, for instance. Later on we will print some text over these rectangles.

Drawing rectangles in a window[edit]

Citing from Wikipedia again:

The client can request a number of graphic operations, such clearing an area, copying an area into another, drawing points, lines, rectangles, and text. Beside clearing, all operations are possible on all drawables, both windows and pixmaps. Most requests for graphic operations include a graphic context, which is a structure that contains the parameters of the graphic operations. A graphic context includes the foreground color, the background color, the font of text, and other graphic parameters. When requesting a graphic operation, the client includes a graphic context.

In other words, as for setting window's attribute, we must use a foreign C structure to set parameters for graphic operations, and then we will feed this structure to the functions that will perform these graphic operations.

There is one difference: instead of operating within a function that allocates memory and creates a pointer to the foreign structure, now we have to explicitly create the Graphic Context, and free it after having used it, with createGC, the interface to XCreateGC, and freeGC, the interface to XFreeGC.

Be careful: if you create a graphic context without freeing it after use, you are going to end up with a sizeable memory leak!

The specific graphic functions we are going to need for drawing a rectangle into our window are:

  1. setForeground the interface to XSetForeground
  2. setBackground the interface to XSetBackground
  3. fillRectangle the interface to XFillRectangle

The first two functions are needed to set the parameters in the Graphic Context. The third one will use this GC for filling a rectangle on the specified window. Just have a look to their type signatures: 

setForeground :: Display -> GC -> Pixel -> IO ()
setBackground :: Display -> GC -> Pixel -> IO ()
fillRectangle :: Display -> Drawable -> GC -> Position -> Position -> Dimension -> Dimension -> IO ()

Okay, this is the function that we will be using for drawing into a window: 

drawInWin :: Display -> Window -> IO ()
drawInWin dpy win = do
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  setForeground dpy gc fgcolor
  fillRectangle dpy win gc 0 0 100 100
  freeGC dpy gc

This will just fill our window with a rectangle at (0, 0) (x, y) coordinates (relatives to the window's internal border), with the same dimensions of our window.

Obviously we can play a bit with rectangles. This version, for instance, will draw 2 rectangles to simulate a blue rectangle with a green border, two pixels width: 

drawInWin :: Display -> Window -> IO ()
drawInWin dpy win = do
  bgcolor <- initColor dpy "green"
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  setForeground dpy gc bgcolor
  fillRectangle dpy win gc 0 0 100 100
  setForeground dpy gc fgcolor
  fillRectangle dpy win gc 2 2 96 96
  freeGC dpy gc

You can use this function on a mapped window. This is our original example, rewritten with this approach: 

module Main where
import Data.Bits
import Graphics.X11.Xlib
import System.Exit (exitWith, ExitCode(..))
import Control.Concurrent (threadDelay)

main :: IO ()
main =
    do dpy <- openDisplay ""
       let dflt = defaultScreen dpy
           scr = defaultScreenOfDisplay dpy
       rootw  <- rootWindow dpy dflt
       win <- mkUnmanagedWindow dpy scr rootw 0 0 100 100
       setTextProperty dpy win "Hello World" wM_NAME 
       mapWindow dpy win
       drawInWin dpy win
       sync dpy False
       threadDelay (10 * 1000000)
       exitWith ExitSuccess

drawInWin :: Display -> Window -> IO ()
drawInWin dpy win = do
  bgcolor <- initColor dpy "green"
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  setForeground dpy gc bgcolor
  fillRectangle dpy win gc 0 0 100 100
  setForeground dpy gc fgcolor
  fillRectangle dpy win gc 2 2 96 96
  freeGC dpy gc

mkUnmanagedWindow :: Display
                  -> Screen
                  -> Window
                  -> Position
                  -> Position
                  -> Dimension
                  -> Dimension
                  -> IO Window
mkUnmanagedWindow dpy scr rw x y w h = do
  let visual = defaultVisualOfScreen scr
  win <- allocaSetWindowAttributes $ 
         \attributes -> do
           set_override_redirect attributes True
           createWindow dpy rw x y w h 0 (defaultDepthOfScreen scr)
                        inputOutput visual cWOverrideRedirect attributes                                
  return win


initColor :: Display -> String -> IO Pixel
initColor dpy color = do

As you see, now mkUnmanagedWindow sets a null border width and does not set any background color. Everything is easily done with rectangles.

Printing a string[edit]

Printing a string to a window requires operating with another foreign C structure, the XFontStruct, which contains all of the information regarding the metrics of font that the X server will use to display our string.

This structure will be used to perform some computations that are required for the correct placement of the text in the window.

As we have seen with the window's attributes and the Graphic Context, we need a function that returns a pointer to this foreign structure, pointer that must be freed after using it.

A pointer to the XFontStruct is returned by loadQueryFont, the interface to the X11 library function XLoadQueryFont().

XLoadQueryFont, which requires the X connection and the font name, will perform two distinct operations: load the needed font and return its id (performed by XLoadFont() which doesn't have a Haskell interface) and query the font to retrieve the XFontStruct (performed by XQueryFont which does have a Haskell interface: queryFont).

The XFontStruct is needed by textExtents, the interface to XTextExtent(), and textWidth, the interface to XTextWidth().

These are their type signatures: 

textExtents :: FontStruct -> String -> (FontDirection, Int32, Int32, CharStruct)
textWidth :: FontStruct -> String -> Int32

Given the FontStruct and the string to be printed, these functions will provide some valuable information. The values returned by the first one are related to font direction and vertical placement, while the second one will return the total width of the string to be printed with that specific font.

This information can be used with the graphic function that will actually draw the text on the window: drawImageString, the interface to XDrawImageString.

There are other version of this string, XDrawText() and [http://www.tronche.com/gui/x/xlib/graphics/drawing-text/XDrawText16.html XDrawText16()] for 16-bit characters.

We are going to use the first one because it will also use the foreground pixel set in the Graphic Context.

Its type signature is: 

drawImageString :: Display -> Drawable -> GC -> Position -> Position -> String -> IO ()

Finally we must remember to free the FontStruct with freeFont the interface to XFreeFont.

We can now write our function to print a string on a window, but first we need to make some small modifications to our drawInWin function, that will now take a string and will load and free the needed FontStruct to be passed to the new printString function: 

drawInWin :: Display -> Window -> String -> IO ()
drawInWin dpy win str = do
  bgcolor <- initColor dpy "green"
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  fontStruc <- loadQueryFont dpy "-misc-fixed-*-*-*-*-10-*-*-*-*-*-*-*"
  setForeground dpy gc bgcolor
  fillRectangle dpy win gc 0 0 200 100
  setForeground dpy gc fgcolor
  fillRectangle dpy win gc 2 2 196 96
  printString dpy win gc fontStruc str
  freeGC dpy gc
  freeFont dpy fontStruc

Here we are loading the "misc-fixed" font. You can select different fonts with the standalone utility: 

xfontsel

As you see the FontStruct retrieved by loadQueryFont is used by printString and then freed.

So, let's look at printString: 

printString :: Display 
             -> Drawable 
             -> GC
             -> FontStruct
             -> String
             -> IO ()
printString dpy d gc fontst str =
    do let strLen = textWidth fontst str
           (_,asc,_,_) = textExtents fontst str
           valign = (100 + fromIntegral asc) `div` 2
           remWidth = 200 - strLen
           offset =  remWidth `div` 2
       fgcolor <- initColor dpy "white"
       bgcolor <- initColor dpy "blue"
       setForeground dpy gc fgcolor
       setBackground dpy gc bgcolor
       drawImageString dpy d gc offset valign str

In the "let" part we use textWidth and textExtents to set vertical and horizontal alignment: this is done by calculating the x and y coordinates for drawImageString. In this example text will be vertically and horizontally centered (take into account that I have also enlarged the window, whose width now is 200 pixels).

For a reference of the meaning of font ascent and descent, and the origins of the rectangle drawn by drawImageString read the par. 8.6 (Drawing Text) of the The Xlib Manual.

You may notice that printString takes a Drawable, which can be either a window or a pixmap (see below).

We can now rewrite our example and finally see some text printed in our window: 

module Main where
import Data.Bits
import Graphics.X11.Xlib
import System.Exit (exitWith, ExitCode(..))
import System.Time
import Control.Concurrent (threadDelay)

main :: IO ()
main =
    do dpy <- openDisplay ""
       let dflt = defaultScreen dpy
           scr = defaultScreenOfDisplay dpy
       rootw  <- rootWindow dpy dflt
       win <- mkUnmanagedWindow dpy scr rootw 0 0 200 100
       setTextProperty dpy win "The Clock" wM_NAME 
       mapWindow dpy win
       drawInWin dpy win =<< date
       sync dpy False
       threadDelay (10 * 1000000)
       exitWith ExitSuccess

date :: IO String
date = do 
  t <- toCalendarTime =<< getClockTime
  return $ calendarTimeToString t

drawInWin :: Display -> Window -> String -> IO ()
drawInWin dpy win str = do
  bgcolor <- initColor dpy "green"
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  fontStruc <- loadQueryFont dpy "-misc-fixed-*-*-*-*-10-*-*-*-*-*-*-*"
  setForeground dpy gc bgcolor
  fillRectangle dpy win gc 0 0 200 100
  setForeground dpy gc fgcolor
  fillRectangle dpy win gc 2 2 196 96
  printString dpy win gc fontStruc str
  freeGC dpy gc
  freeFont dpy fontStruc

printString :: Display 
             -> Drawable 
             -> GC
             -> FontStruct
             -> String
             -> IO ()
printString dpy d gc fontst str =
    do let strLen = textWidth fontst str
           (_,asc,_,_) = textExtents fontst str
           valign = (100 + fromIntegral asc) `div` 2
           remWidth = 200 - strLen
           offset =  remWidth `div` 2
       fgcolor <- initColor dpy "white"
       bgcolor <- initColor dpy "blue"
       setForeground dpy gc fgcolor
       setBackground dpy gc bgcolor
       drawImageString dpy d gc offset valign str

mkUnmanagedWindow :: Display
                  -> Screen
                  -> Window
                  -> Position
                  -> Position
                  -> Dimension
                  -> Dimension
                  -> IO Window
mkUnmanagedWindow dpy scr rw x y w h = do
  let visual = defaultVisualOfScreen scr
  win <- allocaSetWindowAttributes $ 
         \attributes -> do
           set_override_redirect attributes True
           createWindow dpy rw x y w h 0 (defaultDepthOfScreen scr)
                        inputOutput visual cWOverrideRedirect attributes                                
  return win


initColor :: Display -> String -> IO Pixel
initColor dpy color = do
  let colormap = defaultColormap dpy (defaultScreen dpy)
  (apros,real) <- allocNamedColor dpy colormap color
  return $ color_pixel apros

Since we are going to display the system time, I already added a "date" function and increased to width of our window.

Just give it a try. We are almost there. It's a clock, after all.

Updating a window[edit]

If you do not believe that now we have a system clock, just change the main function of the above example with the following two functions and try yourself: 

main :: IO ()
main = do 
  dpy <- openDisplay ""
  let dflt = defaultScreen dpy
      scr = defaultScreenOfDisplay dpy
  rootw  <- rootWindow dpy dflt
  win <- mkUnmanagedWindow dpy scr rootw 0 0 200 100
  setTextProperty dpy win "The Clock" wM_NAME 
  mapWindow dpy win
  updateWin dpy win

updateWin :: Display -> Window -> IO ()
updateWin dpy win = do
  drawInWin dpy win =<< date
  sync dpy False
  threadDelay (1 * 1000000)
  updateWin dpy win

This piece of code just adds the eternal recursive loop and, within this loop, reduces the thread block to 1 second. That's it.

Every second our window will be updated (redrawn).

Now, if you let the clock run for a while, you will notice that sometimes, during an update, the window sort of flickers.

This is due to the fact that we are drawing directly over the window. We need to adopt a better technique: we need to write to a pixmap first, and then copy the pixmap over the window.

Citing from Wikipedia:

"A pixmap is a region of memory that can be used for drawing. Contrary to windows, the contents of pixmaps are not automatically shown on the screen. However, the content of a pixmap (or a part of it) can be transferred to a window and vice versa. This allows for techniques such as double buffering. Most of the graphical operations that can be done on windows can also be done on pixmaps. Windows and pixmaps are collectively named drawables, and their content data resides on the server."

This is not very difficult, and requires a very small change of our drawInWin function.

In order to create the pixmap we will use createPixmap, the interface to XCreatePixmap(), which takes the display connection, the drawable upon which the pixmap is created, the width, the height, and the depth of the screen.

We will then use copyArea, the interface to XCopyArea, to copy the pixmap over the window.

This is the copyArea type signature: 

copyArea :: Display 
         -> Drawable -> Drawable 
         -> GC 
         -> Position -> Position 
         -> Dimension -> Dimension 
         -> Position -> Position 
         -> IO ()

that is to say:

  1. the display connection
  2. the origin and the destination drawables (our pixmap and our window respectively)
  3. the x and y coordinates relative to the origin drawable upper left corner
  4. the width and the height of the area the be copied
  5. the x and y coordinates relative to the upper left corner of the destination drawable where the copied area must be placed

And we will eventually free the pixmap with freePixmap, the interface to XFreePixmap.

Since our printString function may accept either a window or a pixmap, they both are drawables, all we need to do is to change drawInWin accordingly: 

drawInWin :: Display -> Window -> String ->IO ()
drawInWin dpy win str = do
  bgcolor <- initColor dpy "green"
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  fontStruc <- loadQueryFont dpy "-misc-fixed-*-*-*-*-10-*-*-*-*-*-*-*"
  p <- createPixmap dpy win 200 100 (defaultDepthOfScreen (defaultScreenOfDisplay dpy))
  setForeground dpy gc bgcolor
  fillRectangle dpy p gc 0 0 200 100
  setForeground dpy gc fgcolor
  fillRectangle dpy p gc 2 2 196 96
  printString dpy p gc fontStruc str
  copyArea dpy p win gc 0 0 200 100 0 0
  freeGC dpy gc
  freeFont dpy fontStruc
  freePixmap dpy p

Now, all graphic functions take now "p" and not "win". After copyArea everything is freed.

Our clock: 

module Main where
import Data.Bits
import Graphics.X11.Xlib
import System.Exit (exitWith, ExitCode(..))
import System.Time
import Control.Concurrent (threadDelay)

main :: IO ()
main = do 
  dpy <- openDisplay ""
  let dflt = defaultScreen dpy
      scr = defaultScreenOfDisplay dpy
  rootw  <- rootWindow dpy dflt
  win <- mkUnmanagedWindow dpy scr rootw 0 0 200 100
  setTextProperty dpy win "Hello World - The Clock" wM_NAME 
  mapWindow dpy win
  updateWin dpy win

updateWin :: Display -> Window -> IO ()
updateWin dpy win = do
  drawInWin dpy win =<< date
  sync dpy False
  threadDelay (1 * 1000000)
  updateWin dpy win

date :: IO String
date = do 
  t <- toCalendarTime =<< getClockTime
  return $ calendarTimeToString t

drawInWin :: Display -> Window -> String ->IO ()
drawInWin dpy win str = do
  bgcolor <- initColor dpy "green"
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  fontStruc <- loadQueryFont dpy "-misc-fixed-*-*-*-*-10-*-*-*-*-*-*-*"
  p <- createPixmap dpy win 200 100 (defaultDepthOfScreen (defaultScreenOfDisplay dpy))
  setForeground dpy gc bgcolor
  fillRectangle dpy p gc 0 0 200 100
  setForeground dpy gc fgcolor
  fillRectangle dpy p gc 2 2 196 96
  printString dpy p gc fontStruc str
  copyArea dpy p win gc 0 0 200 100 0 0
  freeGC dpy gc
  freeFont dpy fontStruc
  freePixmap dpy p


printString :: Display 
             -> Drawable 
             -> GC
             -> FontStruct
             -> String
             -> IO ()
printString dpy d gc fontst str =
    do let strLen = textWidth fontst str
           (_,asc,_,_) = textExtents fontst str
           valign = (100 + fromIntegral asc) `div` 2
           remWidth = 200 - strLen
           offset =  remWidth `div` 2
       fgcolor <- initColor dpy "white"
       bgcolor <- initColor dpy "blue"
       setForeground dpy gc fgcolor
       setBackground dpy gc bgcolor
       drawImageString dpy d gc offset valign str

mkUnmanagedWindow :: Display
                  -> Screen
                  -> Window
                  -> Position
                  -> Position
                  -> Dimension
                  -> Dimension
                  -> IO Window
mkUnmanagedWindow dpy scr rw x y w h = do
  let visual = defaultVisualOfScreen scr
  win <- allocaSetWindowAttributes $ 
         \attributes -> do
           set_override_redirect attributes True
           createWindow dpy rw x y w h 0 (defaultDepthOfScreen scr)
                        inputOutput visual cWOverrideRedirect attributes                                
  return win


initColor :: Display -> String -> IO Pixel
initColor dpy color = do
  let colormap = defaultColormap dpy (defaultScreen dpy)
  (apros,real) <- allocNamedColor dpy colormap color
  return $ color_pixel apros

Dealing with events[edit]

Now try this.

In updateWin set threadDelay to something like: 

  threadDelay (60 * 1000000)

Run the clock, switch to a console (with Alt+Ctrl+F1) and come back to the X server where the clock is running.

What happened? The window disappeared, and came back after being redrawn by drawInWin.

The problem is that our application does not respond to the events the X server is sending to our window. If a window is covered or anyway no more visible on the screen, when the covered area becomes visible again the X server will send to that window an Expose event, so that the application using that window may redraw it. Since our clock doesn't listen for any event, the window will not be redrawn till a new call to drawInWin is done.

Citing from Wikipedia:

"Events are packets sent by the server to a client to communicate that something the client may be interested in has happened. For example, an event is sent when the user presses a key or clicks a mouse button. Events are not only used for input: for example, events are sent to indicate the creation of new subwindows of a given window. Every event is relative to a window. For example, if the user clicks when the pointer is in a window, the event will be relative to that window. The event packet contains the identifier of that window."

The list of events a window will be reacting too is set as the event mask attribute of that window, and so may be set at creation time, as we have seen for the background pixel, or with XChangeWindowAttributes, or by using selectInput, the interface to XSelectInput.

In any case an event mask, defined as "the bitwise inclusive OR of zero or more of the valid event mask bits", must be specified in a way very similar to the attribute mask specification.

This is the type signature of selectInput: 

selectInput :: Display -> Window -> EventMask -> IO ()

The possible events to be included in the event must, separated by a bitwise inclusive OR, are listed here and here.

For a list of events types refer to the Xlib Manual.

In order to capture Expose events, we will need to set the exposureMask with something like this, right after the new window has been mapped, in our main function: 

  selectInput dpy win exposureMask

This is all we need to do in order to configure the window in such a way that it will receive Expose events.

Our problem is far bigger than that, unfortunately. Our problem, indeed, is that we must update (redraw) our window either in the case of an Expose event is received and when a given amount of time is elapsed. This second requirement was met by blocking our program execution with threadDelay. But when our program is blocked it cannot receive any event.

But if we start listening for events and no Expose event happens, after some time is elapsed we must update our window anyhow.

How can we achieve this?

Just to explain our problem with other words, if we change, in the last example, main and updateWin to listen to events we end up with something like this: 

main :: IO ()
main = do 
  dpy <- openDisplay ""
  let dflt = defaultScreen dpy
      scr = defaultScreenOfDisplay dpy
  rootw  <- rootWindow dpy dflt
  win <- mkUnmanagedWindow dpy scr rootw 0 0 200 100
  setTextProperty dpy win "The Clock" wM_NAME 
  mapWindow dpy win
  selectInput dpy win (exposureMask .|. buttonPress)
  updateWin dpy win

updateWin :: Display -> Window -> IO ()
updateWin dpy win = do
  drawInWin dpy win =<< date
  sync dpy True
  allocaXEvent $ \e -> 
      do nextEvent dpy e
         ev <- getEvent e
         putStrLn $ eventName ev
  updateWin dpy win

In main we added the selectInput call. Note that the event mask includes both Expose events, and mouse button press events (you may specify different types of events).

The second function, updateWin, required more modifications.

Now the sync call takes a True, and not a False any more. This means that when flushing the output buffer all events in the event queue will be discarded. This is necessary otherwise we are going to intercept previous events. For instance, if you change the Boolean to False, you will see a NoExpose event, that is the result of the application of XCopyArea in drawInWin.

Please note the use of allocaXEvent, very similar to the use of allocaSetWindowAttributes, as shown by its type signature: 

allocaXEvent :: (XEventPtr -> IO a) -> IO a

Within allocaXEvent we can use the pointer to the XEvent to:

  1. wait for the next event with nextEvent, the interface to XNextEvent;
  2. get the occurred event with getEvent (which requires X11-extras);
  3. convert the event in a string with eventName (which requires X11-extras);
  4. print the event name to the standard output: if we run our program from the command line, we can see the events received by our window.

I've also removed the threadDelay call. Guess why?

Just give it a run and you'll find out. If sync discards previous events, now nextEvent will block the program execution till an event occurs. If you don't press the mouse button over the window, or force an Expose event to occur, for instance by switching to a text console and back, the thread will be blocked in the safe foreign call to XNextEvent, which, "if the event queue is empty, flushes the output buffer and blocks until an event is received".

This is the implementation of nextEvent: 

-- | interface to the X11 library function @XNextEvent()@.
foreign import ccall safe "HsXlib.h XNextEvent"
	nextEvent    :: Display -> XEventPtr  -> IO ()

How can we unblock nextEvent after a given amount of time is elapsed?

Events and threads[edit]

One possible solution is to use a second thread to ask the X server to send an Expose event after some time.

This is the code: 

module Main where
import Data.Bits
import Graphics.X11.Xlib
import Graphics.X11.Xlib.Extras
import System.Exit (exitWith, ExitCode(..))
import System.Time
import Control.Concurrent (threadDelay, forkIO)

main :: IO ()
main = do 
  dpy <- openDisplay ""
  let dflt = defaultScreen dpy
      scr = defaultScreenOfDisplay dpy
  rootw  <- rootWindow dpy dflt
  win <- mkUnmanagedWindow dpy scr rootw 0 0 200 100
  setTextProperty dpy win "The Clock" wM_NAME 
  mapWindow dpy win
  selectInput dpy win (exposureMask .|. buttonPress)
  updateWin dpy win

updateWin :: Display -> Window -> IO ()
updateWin dpy win = do
  forkIO $ sendExposeEvent dpy win
  drawInWin dpy win =<< date
  sync dpy True
  allocaXEvent $ \e -> 
      do nextEvent dpy e
         ev <- getEvent e
         putStrLn $ eventName ev
  updateWin dpy win

sendExposeEvent :: Display -> Window -> IO ()
sendExposeEvent dpy w = 
    do threadDelay (1 * 1000000)
       allocaXEvent $ \e -> do
         setEventType e expose
         sendEvent dpy w False noEventMask e
       sync dpy False

date :: IO String
date = do 
  t <- toCalendarTime =<< getClockTime
  return $ calendarTimeToString t

drawInWin :: Display -> Window -> String ->IO ()
drawInWin dpy win str = do
  bgcolor <- initColor dpy "green"
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  fontStruc <- loadQueryFont dpy "-misc-fixed-*-*-*-*-10-*-*-*-*-*-*-*"
  p <- createPixmap dpy win 200 100 (defaultDepthOfScreen (defaultScreenOfDisplay dpy))
  setForeground dpy gc bgcolor
  fillRectangle dpy p gc 0 0 200 100
  setForeground dpy gc fgcolor
  fillRectangle dpy p gc 2 2 196 96
  printString dpy p gc fontStruc str
  copyArea dpy p win gc 0 0 200 100 0 0
  freeGC dpy gc
  freeFont dpy fontStruc
  freePixmap dpy p


printString :: Display 
             -> Drawable 
             -> GC
             -> FontStruct
             -> String
             -> IO ()
printString dpy d gc fontst str =
    do let strLen = textWidth fontst str
           (_,asc,_,_) = textExtents fontst str
           valign = (100 + fromIntegral asc) `div` 2
           remWidth = 200 - strLen
           offset =  remWidth `div` 2
       fgcolor <- initColor dpy "white"
       bgcolor <- initColor dpy "blue"
       setForeground dpy gc fgcolor
       setBackground dpy gc bgcolor
       drawImageString dpy d gc offset valign str

mkUnmanagedWindow :: Display
                  -> Screen
                  -> Window
                  -> Position
                  -> Position
                  -> Dimension
                  -> Dimension
                  -> IO Window
mkUnmanagedWindow dpy scr rw x y w h = do
  let visual = defaultVisualOfScreen scr
  win <- allocaSetWindowAttributes $ 
         \attributes -> do
           set_override_redirect attributes True
           createWindow dpy rw x y w h 0 (defaultDepthOfScreen scr)
                        inputOutput visual cWOverrideRedirect attributes                                
  return win


initColor :: Display -> String -> IO Pixel
initColor dpy color = do
  let colormap = defaultColormap dpy (defaultScreen dpy)
  (apros,real) <- allocNamedColor dpy colormap color
  return $ color_pixel apros

This is going to work only if compiled with the ghc flag -threaded, otherwise it will not work.

A clear explanation of why can be found here.

A new nextEvent with asynchronous exceptions[edit]

This is a second solution and was proposed by Spencer Janssen.

It uses a version of nextEvent that will not block in a foreign call. An asynchronous exception will be used to interrupt threadWaitRead.

This is the code: 

import Prelude hiding (catch)
import Data.Bits
import Graphics.X11.Xlib
import Graphics.X11.Xlib.Extras
import System.Exit (exitWith, ExitCode(..))
import System.Time
import Control.Concurrent
import Control.Exception
import System.Posix.Types (Fd(..))


main :: IO ()
main = do 
  dpy <- openDisplay ""
  let dflt = defaultScreen dpy
      scr = defaultScreenOfDisplay dpy
  rootw  <- rootWindow dpy dflt
  win <- mkUnmanagedWindow dpy scr rootw 0 0 200 100
  setTextProperty dpy win "The Clock" wM_NAME 
  mapWindow dpy win
  selectInput dpy win (exposureMask .|. buttonPress)
  updateWin dpy win

-- | A version of nextEvent that does not block in foreign calls.
nextEvent' :: Display -> XEventPtr -> IO ()
nextEvent' d p = do
    pend <- pending d
    if pend /= 0
        then nextEvent d p
        else do
            threadWaitRead (Fd fd)
            nextEvent' d p
 where
    fd = connectionNumber d

-- | The event loop
updateWin :: Display -> Window -> IO ()
updateWin dpy win = do
    t <- forkIO (block go)
    timer t
 where
    -- interrupt the drawing thread every so often
    timer t = do
        threadDelay (1 * 1000000)
        throwTo t (ErrorCall "done")
        timer t
    -- Continuously wait for a timer interrupt or an expose event
    go = do
        drawInWin dpy win =<< date
        catch (unblock $ allocaXEvent $ nextEvent' dpy) (const $ return ())
        go

sendExposeEvent :: Display -> Window -> IO ()
sendExposeEvent dpy w = 
    do threadDelay (1 * 1000000)
       allocaXEvent $ \e -> do
         setEventType e expose
         sendEvent dpy w False noEventMask e
       sync dpy False

date :: IO String
date = do 
  t <- toCalendarTime =<< getClockTime
  return $ calendarTimeToString t

drawInWin :: Display -> Window -> String ->IO ()
drawInWin dpy win str = do
  bgcolor <- initColor dpy "green"
  fgcolor <- initColor dpy "blue"
  gc <- createGC dpy win
  fontStruc <- loadQueryFont dpy "-misc-fixed-*-*-*-*-10-*-*-*-*-*-*-*"
  p <- createPixmap dpy win 200 100 (defaultDepthOfScreen (defaultScreenOfDisplay dpy))
  setForeground dpy gc bgcolor
  fillRectangle dpy p gc 0 0 200 100
  setForeground dpy gc fgcolor
  fillRectangle dpy p gc 2 2 196 96
  printString dpy p gc fontStruc str
  copyArea dpy p win gc 0 0 200 100 0 0
  freeGC dpy gc
  freeFont dpy fontStruc
  freePixmap dpy p


printString :: Display 
             -> Drawable 
             -> GC
             -> FontStruct
             -> String
             -> IO ()
printString dpy d gc fontst str =
    do let strLen = textWidth fontst str
           (_,asc,_,_) = textExtents fontst str
           valign = (100 + fromIntegral asc) `div` 2
           remWidth = 200 - strLen
           offset =  remWidth `div` 2
       fgcolor <- initColor dpy "white"
       bgcolor <- initColor dpy "blue"
       setForeground dpy gc fgcolor
       setBackground dpy gc bgcolor
       drawImageString dpy d gc offset valign str

mkUnmanagedWindow :: Display
                  -> Screen
                  -> Window
                  -> Position
                  -> Position
                  -> Dimension
                  -> Dimension
                  -> IO Window
mkUnmanagedWindow dpy scr rw x y w h = do
  let visual = defaultVisualOfScreen scr
  win <- allocaSetWindowAttributes $ 
         \attributes -> do
           set_override_redirect attributes True
           createWindow dpy rw x y w h 0 (defaultDepthOfScreen scr)
                        inputOutput visual cWOverrideRedirect attributes                                
  return win


initColor :: Display -> String -> IO Pixel
initColor dpy color = do
  let colormap = defaultColormap dpy (defaultScreen dpy)
  (apros,real) <- allocNamedColor dpy colormap color
  return $ color_pixel apros
Retrieved from "https://wiki.haskell.org/index.php?title=X_window_programming_in_Haskell&oldid=63485"