User:Michiexile/MATH198/Lecture 3

These notes cover material dispersed in several places of Awodey. The definition of a functor is on page 8. More on functors and natural transformations comes in sections 7.1-7.2, 7.4-7.5, 7.7-7.10.

Functors[edit]

We've spent quite a bit of time talking about categories, and special entities in them - morphisms and objects, and special kinds of them, and properties we can find.

And one of the main messages visible so far is that as soon as we have an algebraic structure, and homomorphisms, this forms a category. More importantly, many algebraic structures, and algebraic theories, can be captured by studying the structure of the category they form.

So obviously, in order to understand Category Theory, one key will be to understand homomorphisms between categories.

Homomorphisms of categories[edit]

A category is a graph, so a homomorphism of a category should be a homomorphism of a graph that respect the extra structure. Thus, we are led to the definition:

Definition A functor $F : C \to D$ from a category $C$ to a category $D$ is a graph homomorphism $F_{0}, F_{1}$ between the underlying graphs such that for every object $X \in C_{0}$ :

$F_{1} (1_{X}) = 1_{F_{0} (X)}$
$F_{1} (g f) = F_{1} (g) F_{1} (f)$

Note: We shall frequently use $F$ in place of $F_{0}$ and $F_{1}$ . The context should suffice to tell you whether you are mapping an object or a morphism at any given moment.

On Wikipedia: [1]

Examples[edit]

A homomorphism $f : M \to N$ of monoids is a functor of the corresponding one-object categories $F : C (M) \to C (N)$ . The functor takes the single object to the single object, and acts on morphisms by $F (g) = f (g)$ .

A homomorphism $f : P \to Q$ of posets is a functor $F : C (P) \to C (Q)$ of the corresponding category. We have $f (x) \leq f (y)$ if $x \leq y$ , so if $g \in H o m_{P} (x, y)$ then $F (g) \in H o m_{Q} (f (x), f (y))$ .

If we pick some basis for every vector space, then this gives us a functor $F$ from $V e c t$ to the category with objects integers and morphisms matrices by:

$F_{0} (V) = \dim V$
$F_{1} (f)$ is the matrix representing $f$ in the matrices chosen.

This example relies on the axiom of choice.

Interpreting functors in Haskell[edit]

One example of particular interest to us is the category Hask. A functor in Hask is something that takes a type, and returns a new type. Not only that, we also require that it takes arrows and return new arrows. So let's pick all this apart for a minute or two.

Taking a type and returning a type means that you are really building a polymorphic type class: you have a family of types parametrized by some type variable. For each type a, the functor data F a = ... will produce a new type, F a. This, really, is all we need to reflect the action of $F_{0}$ .

The action of $F_{1}$ in turn is recovered by requiring the parametrized type F a to implement the Functor typeclass. This typeclass requires you to implement a function fmap ::i (a -> b) -> F a -> F b. This function, as the signature indicates, takes a function f :: a -> b and returns a new function fmap f :: F a -> F b.

The rules we expect a Functor to obey seem obvious: translating from the categorical intuition we arrive at the rules

fmap id = id and
fmap (g . f) = fmap g . fmap f

Now, the real power of a Functor still isn't obvious with this viewpoint. The real power comes in approaching it less categorically.

A Haskell functor is a polymorphic type. In a way, it is an prototypical polymorphic type. We have some type, and we change it, in a meaningful way. And the existence of the Functor typeclass demands of us that we find a way to translate function applications into the Functor image. We can certainly define a boring Functor, such as

data Boring a = Boring
instance Functor Boring where
  fmap f = const Boring

but this is not particularly useful. Almost all Functor instances will take your type and include it into something different, something useful. And it does this in a way that allows you to lift functions acting on the type it contains, so that they transform them in their container.

And the choice of words here is deliberate. Functors can be thought of as data containers, their parameters declaring what they contain, and the fmap implementation allowing access to the contents. Lists, trees with node values, trees with leaf values, Maybe, Either all are Functors in obvious manners.

data List a = Nil | Cons a (List a) 
instance Functor List where
  fmap f Nil = Nil
  fmap f (Cons x lst) = Cons (f x) (fmap f lst)

data Maybe a = Nothing | Just a
instance Functor Maybe where
  fmap f Nothing = Nothing
  fmap f (Just x) = Just (f x)

data Either b a = Left b | Right a
instance Functor (Either b) where
  fmap f (Left x) = Left x
  fmap f (Right y) = Right (f y)

data LeafTree a = Leaf a | Node [LeafTree a]
instance Functor LeafTree where
  fmap f (Node subtrees) = Node (map (fmap f) subtrees)
  fmap f (Leaf x) = Leaf (f x)

data NodeTree a = Leaf | Node a [NodeTree a]
instance Functor NodeTree where
  fmap f Leaf = Leaf
  fmap f (Node x subtrees) = Node (f x) (map (fmap f) subtrees)

The category of categories[edit]

We define a category $C a t$ by setting objects to be all small categories, and arrows to be all functors between them. Being graph homomorphisms, functors compose, their composition fulfills all requirements on forming a category. It is sometimes useful to argue about a category $C A T$ of all small and most large categories. The issue here is that allowing $C A T \in C A T_{0}$ opens up for set-theoretical paradoxes.

Isomorphisms in Cat and equivalences of categories[edit]

The definition of an isomorphism holds as is in $C a t$ . However, isomorphisms of categories are too restrictive a concept.

To see this, recall the category $M o n o i d$ , where each object is a monoid, and each arrow is a monoid homomorphism. We can form a one-object category out of each monoid, and the method to do this is functorial - i.e. does the right thing to arrows to make the whole process a functor.

Specifically, if $h : M \to N$ is a monoid homomorphism, we create a new functor $C (h) : C (M) \to C (N)$ by setting $C (h)_{0} (*) = *$ and $C (h)_{1} (m) = h (m)$ . This creates a functor from $M o n o i d$ to $C a t$ . The domain can be further restricted to a full subcategory $O O C$ of $C a t$ , consisting of all the 1-object categories. We can also define a functor $U : O O C \to M o n o i d$ by $U (C) = C_{1}$ with the monoidal structure on $U (C)$ given by the composition in $C$ . For an arrow $F : A \to B$ we define $U (F) = F_{1}$ .

These functors take a monoid, builds a one-object category, and hits all of them; and takes a one-object category and builds a monoid. Both functors respect the monoidal structures - yet these are not an isomorphism pair. The clou here is that our construction of $C (M)$ from $M$ requires us to choose something for the one object of the category. And choosing different objects gives us different categories.

Thus, the composition $C U$ is not the identity; there is no guarantee that we will pick the object we started with in the construction in $C$ . Nevertheless, we would be inclined to regard the categories $M o n o i d$ and $O O C$ as essentially the same. The solution is to introduce a different kind of sameness: Definition A functor $F : C \to D$ is an equivalence of categories if there is a functor $G : D \to C$ and:

A family $u_{C} : C \to G (F (C))$ of isomorphisms in $C$ indexed by the objects of $C$ , such that for every arrow $f : C \to C^{'} : G (F (f)) = u_{C^{'}} \circ f \circ u_{C}^{- 1}$ .
A family $u_{D} : D \to F (G (D))$ of isomorphisms in $D$ indexed by the objects of $D$ , such that for every arrow $f : D \to D^{'} : F (G (f)) = u_{D^{'}} \circ f \circ u_{D}^{- 1}$ .

The functor $G$ in the definition is called a pseudo-inverse of $F$ .

Natural transformations[edit]

The families of morphisms required in the definition of an equivalence show up in more places. Suppose we have two functors $F : A \to B$ and $G : A \to B$ . Definition $A$ natural transformation $α : F \to G$ is a family of arrows $α a : F (a) \to G (a)$ indexed by the objects of $A$ such that for any arrow $s : a \to b$ in $G (s) \circ α a = α b \circ F (s)$ (draw diagram)

The commutativity of the corresponding diagram is called the naturality condition on $α$ , and the arrow $α a$ is called the component of the natural transformation $α$ at the object $a$ .

Given two natural transformations $α : F \to G$ and $β : G \to H$ , we can define a composition $β \circ α$ componentwise as $(β \circ α) (a) = β a \circ α a$ .

Proposition The composite of two natural transformations is also a natural transformation.

Proposition Given two categories $C, D$ the collection of all functors $C \to D$ form a category $F u n c (C, D)$ with objects functors and morphisms natural transformations between these functors.

Note that this allows us to a large degree to use functors to define entities we may otherwise have defined using large and involved definitions. Doing this using the categorical language instead mainly gives us a large number of facts for free: we don't have to verify, say, associativity of composition of functors if we already know them to be functors.

Example Recall our original definition of a graph as two collections and two maps between them. We can define a category GraphS:

with the two arrows named $s$ and $t$ . It is a finite category with 2 objects, and 4 arrows. Now, a small graph can be defined to be just a Functor $G r a p h S \to S e t$ .

In order to define more intricate structures this way, say Categories, or algebraic structures, we'd need more tools - which we shall find in later lectures. This approach to algebraic definition develops into an area called Sketch theory.

The idea, there, is that theories are modelled by specific categories - such as $G r a p h S$ above, and actual instances of the objects they model appear as functors.

With this definition, since a graph is just a functor $G r a p h S \to S e t$ , and we get graph homomorphisms for free: a graph homomorphism is just a natural transformation.

And anything we can prove about functors and natural transformations thus immediately gives a corresponding result for graphs and graph homomorphisms.

On Wikipedia, see: [2]. Sketch theory, alas, has a painfully incomplete Wikipedia article.

Properties of functors[edit]

The process of forming homsets within a category $C$ gives, for any object $A$ , two different functors $H o m (A, -)$ : $X \mapsto H o m (A, X)$ and $H o m (-, A) : X \mapsto H o m (X, A)$ . Functoriality for $H o m (A, -)$ is easy: $H o m (A, f)$ is the map that takes some $g : A \to X$ and transforms it into $f g : A \to Y$ .

Functoriality for $H o m (-, A)$ is more involved. We can view this as a functor either from $C^{o p}$ , or as a different kind of functor. If we just work with $C^{o p}$ , then no additional definitions are needed - but we need an intuition for the dual categories.

Alternatively, we introduce a new concept of a contravariant functor. A contravariant functor $F : C \to D$ is some map of categories, just like a functor is, but such that $F (1 [X]) = 1 [F (X)]$ , as usual, but such that for a $f : A \to B$ , the functor image is some $F (f) : F (B) \to F (A)$ , and the composition is $F (g f) = F (f) F (g)$ . The usual kind of functors are named covariant.

A functor $F : C \to D$ is faithful if the induced mapping

H o m_{C} (A, B) \to H o m_{D} (F A, F B)

is injective for all $A, B \in C_{0}$ .

A functor $F : C \to D$ is full if the induced mapping

H o m_{C} (A, B) \to H o m_{D} (F A, F B)

is surjective for all $A, B \in C_{0}$ .

Note that a full subcategory is a subcategory so that the embedding functor is both full and faithful.

See also entries in the list of Types of Functors on the Wikipedia page for Functors [3].

Preservation and reflection[edit]

We say that a functor $F : C \to D$ preserves a property $P$ , if whenever $P$ holds in the category $C$ , it does so for the image of $F$ in $D$ .

Thus, the inclusion functor for the category of finite sets into the category of sets preserves both monomorphisms and epimorphisms. Indeed, these properties, in both categories, correspond to injective and surjective functions, respectively; and a surjective (injective) function of finite sets is still surjective (injective) when considered for sets in general.

As another example, consider the category $2$ given by $A \to B$ , with the single non-identity arrow named $f$ . All arrows in this category are both monomorphic and epimorphic. We can define a functor $F : 2 \to S e t$ through $A \mapsto {1, 2}$ , $B \mapsto {3, 4}$ and $f$ mapping to the set function that takes all elements to the value $3$ . The resulting constant map $F (f)$ is neither epic nor monic, while the morphism $f$ is both.

However, there are properties that functors do preserve:

Proposition Every functor preserves isomorphisms.

Proof Suppose $f : X \to Y$ is an isomorphism with inverse $f^{- 1}$ . Then $F (f)$ has inverse $F (f^{- 1})$ . Indeed, $F (f) F (f^{- 1}) = F (f f^{- 1}) = F (1_{Y}) = 1_{F (Y)}$ and $F (f^{- 1}) F (f) = F (f^{- 1} f) = F (1_{X}) = 1_{F (X)}$ . QED

We say that a functor $F : C \to D$ reflects a property $P$ , if whenever $F (f)$ has that property, so does $f$ .

A functor $F : C \to D$ is representative if every object in $D$ is isomorphic to some $F (X)$ for $X \in C_{0}$ .

Homework[edit]

Complete homework is by 4 out of 9 complete solutions. Partial credit will be given.

Show that the category of vectorspaces is equivalent to the category with objects integers and arrows matrices.
Prove the propositions in the section on natural transformations.
Prove that listToMaybe :: [a] -> Maybe a is a natural transformation from the list functor to the maybe functor. Is catMaybes a natural transformation? Between which functors?
Find two more natural transformations defined in the standard Haskell library. Find one polymorphic function that is not a natural transformation.
Write a functor instance for data F a = F (Int -> a)
Write a functor instance for data F a = F ((Int -> a) -> Int)
Write a natural transformation from Maybe a to Either () a. Is this a natural isomorphism? If so, what is its inverse? If not, why not?
Write a natural transformation from [a] to (Maybe a, Maybe a). Is this a natural isomorphism? If so, what is its inverse? If not, why not?
* Recall that a category is called discrete if it has no arrows other than the identities. Show that a small category $A$ is discrete if and only if every set function $A_{0} \to B_{0}$ , for every small category $B$ , is the object part of a unique functor $A \to B$ . Analogously, we define a small category $B$ to be indiscrete if for every small category $A$ , every set function $A_{0} \to B_{0}$ is the object part of a unique functor $A \to B$ . Characterise indiscrete categories by the objects and arrows they have.
* We could write a pretty printer, or XML library, using the following data type as the core data type:

data ML a = Tag a (ML a) | 
            Str String   |
            Seq [ML a]   |
            Nil

With this, we can use a specific string-generating function to generate the tagged marked up text, such as, for instance:

prettyprint (Tag tag ml) = "<" ++ show tag ++ ">" ++ prettyprint ml ++ "</" ++ show tag ++ ">"
prettyprint (Str s) = s
prettyprint (Seq []) = ""
prettyprint (Seq (m:ms)) = prettyprint m ++ "\n" ++ prettyprint (Seq ms)
prettyprint Nil = ""

Write an instance of Functor that allows us to apply changes to the tagging type. Then, using the following tagging types:

data HTMLTag = HTML | BODY | P | H1 | CLASS String deriving (Show)
data XMLTag = DOCUMENT | HEADING | TEXT deriving (Show)

write a function htmlize :: ML XMLTag -> ML HTMLTag and use it to generate a html document out of:

Tag DOCUMENT 
  Seq [
    Tag HEADING
      String "Nobel prize for chromosome find",
    Tag TEXT
      String "STOCKHOLM (Reuters) - Three Americans won the Nobel prize for medicine on Monday for revealing the existence and nature of telomerase, an enzyme which helps prevent the fraying of chromosomes that underlies aging and cancer.",
    Tag TEXT
      String "Australian-born Elizabeth Blackburn, British-born Jack Szostak and Carol Greider won the prize of 10 million Swedish crowns ($1.42 million), Sweden's Karolinska Institute said.",
    Tag TEXT
      String "'The discoveries ... have added a new dimension to our understanding of the cell, shed light on disease mechanisms, and stimulated the development of potential new therapies,' it said.",
    Tag TEXT
      String "The trio's work laid the foundation for studies that have linked telomerase and telomeres -- the small caps on the end of chromosomes -- to cancer and age-related conditions.",
    Tag TEXT
      String "Work on the enzyme has become a hot area of drug research, particularly in cancer, as it is thought to play a key role in allowing tumor cells to reproduce out of control.",
    Tag TEXT
      String "One example, a so-called therapeutic vaccine that targets telomerase, in trials since last year by drug and biotech firms Merck and Geron, could yield a treatment for patients with tumors including lung and prostate cancer.",
    Tag TEXT
      String "The Chief Executive of Britain's Medical Research Council said the discovery of telomerase had spawned research of 'huge importance' to the world of science and medicine.",
    Tag TEXT
      String "'Their research on chromosomes helped lay the foundations of future work on cancer, stem cells and even human aging, areas that continue to be of huge importance,' Sir Leszek Borysiewicz said in a statement."
  ]